xtbalance2 usage

[Martin Eden]

Hello, Stata users! I am trying to make balanced panel data from my unbalanced one. As I found on the internet, xtbalance2 is the solving key.
Unfortunately, I didn't find any relevant information about details of using this command. For instance, I run Stata and create panel data (random effects). After that, do I need to name/store the results? How actually to use xtbalance2? This command delete all observations unavailable for any particular year and leave only observations available for all years, right?

Thank you in advance,
Martin

[George Ford]

xtbalance2 [varlist] [if] [in] , generate(newvarname) [optimisation(string) ]

so you'd basically put your y and Xs in [varlist] and any if conditions. name your variable that identifies the balanced panel. optimization chooses whether to max cross sections (N) or times (T) or both (NT).

you'd then run your model with if "newvarname"==1, or "keep newvarname==1" to drop unbalanced observations.

the data must be xtset to establish the id and time variables.

clear all
version 18

set obs 100
g id = _n
g fe1 = rchi2(5)
g fe2 = rchi2(5)
expand 20
bys id: g time = _n

g x1 = rnormal()
g x2 = rnormal()

replace x1 = . if inrange(id,1,10) & runiform()>0.8

g y = fe1 + 2*x1 - 4*x2 + rnormal()

xtset id time

xtbalance2 y x1 x2 , generate(keepersT) opt(T)
xtbalance2 y x1 x2 , generate(keepersN) opt(N)
xtbalance2 y x1 x2 , generate(keepersNT) opt(NT)


eststo e1: qui xtreg y x1 x2 , fe
eststo e2: qui xtreg y x1 x2 if keepersT , fe
eststo e3: qui xtreg y x1 x2 if keepersN , fe
eststo e4: qui xtreg y x1 x2 if keepersNT , fe

esttab e1 e2 e3 e4, mtitle(All KeepT KeepN KeepTN) stats(N N_g g_max g_min g_avg)

[Andrew Musau]

Here are definitions of a balanced panel from the manual:

unbalanced, weakly balanced, or strongly balanced; panels are strongly balanced if they all have the same time values, weakly balanced if same number of observations but different time values, otherwise unbalanced

xtbalance2 is from SSC (FAQ Advice #12).

How actually to use xtbalance2? This command delete all observations unavailable for any particular year and leave only observations available for all years, right?

So, to answer your question while taking into account the above definitions, the panel would be considered balanced if applying the above deletion results in the same time values (strongly balanced) or the same number of observations (weakly balanced) across panels. Otherwise, doing so will not necessarily create a balanced panel. In this sense, creating a balanced panel from an unbalanced one could obliterate your sample. Most estimators can handle unbalanced panels, so balancing the panel is not usually necessary.