etable - is there a way to add the results from margins command in thee results table?

[Preety Bhogal]

Hi All,

I am trying to create a results table using etable command. I have also run the margins command to get the net effects of a variable and I want to include those results in the table with regressions coefficients. Is there a way to include the marginal effects in the table? Thanks in advance.

Regards,
Preety

[Richard Williams]

Check out the estadd command, which is part of the user-written estout package.

https://repec.sowi.unibe.ch/stata/es...lp-estadd.html

[Jeff Pitblado (StataCorp)]

Without some data and an example or detailed description, it is not clear exactly what table you are looking to build.

Let's use some data and code to show some basic things you can do with etable and collect for building your table. In the following I modify an example in the manual entry [R] etable. First I load some data, fit a linear regression, and store its results under the name fit, then use margins to compute the marginal effects. In the call to margins I use option post so that it posts its results to e(), which I then store under the name dydx. Finally, I use etable to build a table from these two sets of estimation results.

webuse nhanes2l

regress bpsystol c.age##c.age weight i.region
estimates store fit

margins, dydx(*) post
estimates store dydx

etable, estimates(fit dydx) column(estimates)

Here is the resulting table.

-----------------------------------------
                            fit     dydx 
-----------------------------------------
Age (years)                -0.359   0.660
                          (0.082) (0.011)
Age (years) # Age (years)   0.011        
                          (0.001)        
Weight (kg)                 0.428   0.428
                          (0.013) (0.013)
Region                                   
  MW                       -0.364  -0.364
                          (0.560) (0.560)
  S                        -0.583  -0.583
                          (0.556) (0.556)
  W                        -1.057  -1.057
                          (0.567) (0.567)
Intercept                  90.338        
                          (1.880)        
Number of observations      10351   10351
-----------------------------------------

You can then use the collect suite of commands to further customize your table. For example, I use the following command to restrict the colname dimension to the age coefficients and effects.

collect style autolevels colname age age#age
collect preview

Here is the resulting table.

-----------------------------------------
                            fit     dydx 
-----------------------------------------
Age (years)                -0.359   0.660
                          (0.082) (0.011)
Age (years) # Age (years)   0.011        
                          (0.001)        
Number of observations      10351   10351
-----------------------------------------

[Preety Bhogal]

Hi Jeff Pitblado (StataCorp) Thank you so much for your response. It is indeed helpful!

I have another question and would appreciate your help. I have read and re-read etable help document multiple times, but I still have no solution to my issue. I am trying to create a table using etable command where I can stack regression results from OLS and IV command vertically. For instance, 2 different OLS results arranged in columns shown in panel A and 2 different IV regressions shown arranged in columns and shown in panel B. Panel A and B are arranged vertically. B on top of A. Is it possible to do something like this with etable in Stata? Moreover, is there a way to change the variable names (how they are displayed particularly the interaction terms) in etable? Thank you again!

[Jeff Pitblado (StataCorp)]

If you provide a working example, comprised of data and Stata code, for fitting the models you are interested in, I'm sure we can help you arrange your results into the table you describe.

Given your description, I think we will need to use the collect suite of commands. etable arranges each set of estimation results in their own column, so even if you use etable to put your fitted models into a collection, you still need collect to rearrange things as you describe.

[Preety Bhogal]

Thank you Jeff Pitblado (StataCorp). I greatly appreciate your response. Here's the data example.

* Example generated by -dataex-. For more info, type help dataex
clear
input str7 NAICS_6 float(listtime expw_hic_iv1 CR_list BEC_new non_hom value_of_shipments_2015 emp_change) double trade_balance float(naics2dumlist naics4dumlist listtimedum list_CHN_1 list_CHN_2 list_CHN_3 list_CHN_4 iv_CHN_1 iv_CHN_2 iv_CHN_3 iv_CHN_4)
"111110" 1 0        0 1 0 . . 0 1   1 1 7.236979        0        0        0 0 0 0 0
"111110" 2 0        0 1 0 . . 0 3  19 2        0 7.706713        0        0 0 0 0 0
"111110" 3 0        1 1 0 . . 0 6  91 3        0        0 8.299247        0 0 0 0 0
"111110" 4 0        . 1 0 . . 0 8 127 4        0        0        0 8.739226 0 0 0 0
"111120" 1 0        0 1 1 . . 0 1   1 1 7.236979        0        0        0 0 0 0 0
"111120" 2 0        0 1 1 . . 0 3  19 2        0 7.706713        0        0 0 0 0 0
"111120" 3 0 .9615384 1 1 . . 0 6  91 3        0        0 8.299247        0 0 0 0 0
"111120" 4 0        1 1 1 . . 0 8 127 4        0        0        0 8.739226 0 0 0 0
"111130" 1 0        0 0 1 . . 0 1   1 1 7.236979        0        0        0 0 0 0 0
"111130" 2 0        0 0 1 . . 0 3  19 2        0 7.706713        0        0 0 0 0 0
"111130" 3 0 .7530864 0 1 . . 0 6  91 3        0        0 8.299247        0 0 0 0 0
"111130" 4 0      .15 0 1 . . 0 8 127 4        0        0        0 8.739226 0 0 0 0
"111140" 1 0        0 1 0 . . 0 1   1 1 7.236979        0        0        0 0 0 0 0
"111140" 2 0        0 1 0 . . 0 3  19 2        0 7.706713        0        0 0 0 0 0
"111140" 3 0 .6190476 1 0 . . 0 6  91 3        0        0 8.299247        0 0 0 0 0
"111140" 4 0      .75 1 0 . . 0 8 127 4        0        0        0 8.739226 0 0 0 0
"111150" 1 0        0 1 0 . . 0 1   1 1 7.236979        0        0        0 0 0 0 0
"111150" 2 0        0 1 0 . . 0 3  19 2        0 7.706713        0        0 0 0 0 0
"111150" 3 0 .8333333 1 0 . . 0 6  91 3        0        0 8.299247        0 0 0 0 0
"111150" 4 0        1 1 0 . . 0 8 127 4        0        0        0 8.739226 0 0 0 0
end

The regressions I am trying to run are OLS and IV. I want to save OLS regressions in Panel A and IV regressions in Panel B (arranged vertically).
Regressions I am running are as follows:
OLS regressions - 2 different versions arranged in columns 1 and 2
reghdfe CR_list list_CHN_1 list_CHN_2 list_CHN_3 list_CHN_4 [aw=value_of_shipments_2015], absorb(naics2dumlist) vce(cluster naics4dumlist)
reghdfe CR_list list_CHN_1 list_CHN_2 list_CHN_3 list_CHN_4 i.listtimedum#c.BEC_new [aw=value_of_shipments_2015], absorb(naics2dumlist) vce(cluster naics4dumlist)
IV regressions - 2 different versions arranged in columns 1 and 2
ivreg2 CR_list i.naics2dumlist (list_CHN_1 list_CHN_2 list_CHN_3 list_CHN_4=iv_CHN_1 iv_CHN_2 iv_CHN_3 iv_CHN_4) [aw=value_of_shipments_2015], robust cluster(naics4dumlist) endog(list_CHN_1 list_CHN_2 list_CHN_3 list_CHN_4)
ivreg2 CR_list i.naics2dumlist (list_CHN_1 list_CHN_2 list_CHN_3 list_CHN_4=iv_CHN_1 iv_CHN_2 iv_CHN_3 iv_CHN_4) i.listtimedum#c.BEC_new [aw=value_of_shipments_2015], robust cluster(naics4dumlist) endog(list_CHN_1 list_CHN_2 list_CHN_3 list_CHN_4)


I want to create these tables for LaTeX. Is it possible to create them in Latex as it is? Thank you again for helping me out with this.

Kind Regards,
Preety

[Jeff Pitblado (StataCorp)]

The data you provide is not sufficient to fit any of the models you provided.

However, given the estimation commands you provided, I think I can compose some code with publicly available data that meets your description.

Using data from the help file for Stata's ivregress command, the following uses regress (for OLS) and ivregress (for IV) to fit slightly different model specifications and arranges the estimated coefficients and standard errors as requested.

webuse hsng2

collect clear

* replace the default style with the one for -etable-, it uses fixed
* decimal formats and puts parens around standard errors
collect style use etable, replace

* We are going to collect results from each model fit, adding custom
* tags that will allow us to arrange the coefficients and standard erros
* as requested.  The custom tag dimensions are 'panel' for row blocks A
* and B, and 'spec' for model specifications we will place in columns 1 and 2.

regress rent pcturban c.popgrow
collect get _r_b _r_se, tags(panel[A] spec[1])

regress rent pcturban c.popgrow##c.popgrow
collect get _r_b _r_se, tags(panel[A] spec[2])

ivregress 2sls rent pcturban (c.popgrow = c.faminc##c.faminc i.region)
collect get _r_b _r_se, tags(panel[B] spec[1])

ivregress 2sls rent pcturban (c.popgrow##c.popgrow = c.faminc##c.faminc i.region)
collect get _r_b _r_se, tags(panel[B] spec[2])

* Use our custom dimensions and other built-in dimensions to stack the
* panels A and B, while keeping the model specifications in the columns.
* The -etable- style defines rules for significance "stars", so we need
* to put "stars[value]" in the layout specification to ensure that all
* coefficients show up in the table.  If you want to see the stars,
* change "stars[value]" to "stars".

collect layout (panel[B A]#colname#result) (spec#stars[value])

* Publish our table to LaTeX.
collect export table.tex, replace

Here is the resulting table.

-------------------------------------
                        1        2   
-------------------------------------
B                                    
  pcturban             1.377    1.708
                     (0.265)  (0.550)
  popgrow              0.566    2.053
                     (0.341)  (2.137)
  popgrow # popgrow            -0.036
                              (0.052)
  _cons              133.341  104.053
                    (17.923) (45.838)
A                                    
  pcturban             1.351    1.339
                     (0.270)  (0.297)
  popgrow              0.739    0.662
                     (0.270)  (0.771)
  popgrow # popgrow             0.002
                              (0.015)
  _cons              132.256  133.604
                    (18.353) (22.467)
-------------------------------------

Here is a screenshot of the table from the PDF document produced by running pdflatex table.tex.

[Preety Bhogal]

Thanks, Jeff Pitblado (StataCorp), for showing a detailed example. My sincere apologies for a delayed response. I have tried the collect command on my data and have a few follow-up questions. I will be grateful for your suggestions.
1. I do not want to show coefficients for all the variables in the table. Is there a way to keep only the essential variables?
2. How to change the names of the variables and call them differently?
3. I wanted to write "Panel A" instead of "A" and I tried that in the data. However, I soon realized that Stata does not allow for gaps between words. So, I changed the panel title to Panel_A_OLS. Is there a possibility to write OLS under Panel A?
4. I wanted to write OLS with spec[OLS] and IV with spec[IV], but that creates two separate columns. I want the same column to show different headings for different panels.
5. I ran a few tests for the instruments for IV regression. Earlier I was showing these test-stat as part of the table with etable command. However, with collect, is there a way to add them towards the end of the two panels using mstat()?
6. How to add a title to the table and title for Panels?

I will greatly appreciate your help on this. I am currently writing my thesis and need to create these tables in Sata and export in LaTex later for easier access. Looking forward to your response. Thanks!

Kind Regards,
Preety