exporting ATT for psmatch2 using outreg2 or esttab

[Francisco Nobre]

Hello,

I am trying to export the ATT for psmatch2 using the following:
psmatch2 treatment x1 x2 x3, out(depvar) common
outreg2 using propensity_matching.tex, append

However, it just returns the difference and S.E for the unmatched, while I want that information but for the ATT . How can I export it, either with outreg2 or esttab?


Many thanks.

[Andrew Musau]

No one has responded to your question, most likely due to the lack of a data example. See FAQ Advice #12 on how best to pose questions in this forum. Also note that psmatch2, estout and outreg2 are from SSC, as you are asked to explain in the referenced FAQ.

webuse cattaneo2, clear
psmatch2 mbsmoke mmarried c.mage##c.mage fbaby medu, out(bweight) 
*ssc install erepost, replace
mat b=e(b)
mat b[1,1]= r(att)
mat V= e(V)
mat V[1,1]= r(seatt)^2
erepost b=b V=V, rename
esttab, se keep(_treated)

Res.:

. psmatch2 mbsmoke mmarried c.mage##c.mage fbaby medu, out(bweight) 

Probit regression                                       Number of obs =  4,642
                                                        LR chi2(5)    = 380.48
                                                        Prob > chi2   = 0.0000
Log likelihood = -2040.5061                             Pseudo R2     = 0.0853

-------------------------------------------------------------------------------
      mbsmoke | Coefficient  Std. err.      z    P>|z|     [95% conf. interval]
--------------+----------------------------------------------------------------
     mmarried |  -.6484821   .0526991   -12.31   0.000    -.7517705   -.5451938
         mage |   .1744327   .0352437     4.95   0.000     .1053562    .2435092
              |
c.mage#c.mage |  -.0032559   .0006462    -5.04   0.000    -.0045224   -.0019894
              |
        fbaby |  -.2175962   .0491066    -4.43   0.000    -.3138433    -.121349
         medu |  -.0863631   .0098692    -8.75   0.000    -.1057064   -.0670198
        _cons |  -1.558255   .4511589    -3.45   0.001     -2.44251       -.674
-------------------------------------------------------------------------------
----------------------------------------------------------------------------------------
        Variable     Sample |    Treated     Controls   Difference         S.E.   T-stat
----------------------------+-----------------------------------------------------------
         bweight  Unmatched | 3137.65972   3412.91159  -275.251871   21.4528037   -12.83
                        ATT | 3137.65972   3329.16204  -191.502315   54.3323725    -3.52
----------------------------+-----------------------------------------------------------
Note: S.E. does not take into account that the propensity score is estimated.

           | psmatch2:
 psmatch2: |   Common
 Treatment |  support
assignment | On suppor |     Total
-----------+-----------+----------
 Untreated |     3,778 |     3,778 
   Treated |       864 |       864 
-----------+-----------+----------
     Total |     4,642 |     4,642 


. 
. esttab, se keep(_treated)

----------------------------
                      (1)   
                  bweight   
----------------------------
_treated           -191.5***
                  (54.33)   
----------------------------
N                    4642   
----------------------------
Standard errors in parentheses
* p<0.05, ** p<0.01, *** p<0.001

.