ivprobit and etable command

[Preety Bhogal]

Hi All,
I am trying to store the estimates of ivprobit model using etable. However, I am experiencing some issues in storing these estimates.
When I run the ivprobit command, I get estimates for 5 variables. However, when the table is produced, I have 25 variables estimated and displayed. I am not sure why these extra estimates are produced.

The command used is:

ivprobit dummy_list i.hs2dum (list_CHN_1 list_CHN_2 list_CHN_3 list_CHN_4=iv_CHN_1 iv_CHN_2 iv_CHN_3 iv_CHN_4) BEC_new different_con change_2011_2015_unweighted weighted_trade_balance_broad, vce(robust)
eststo IV
estadd local FE = "Yes": IV


etable, est(OLS IV) mstat(N) mstat(p_exog, label("Exogeneity test Wald p-value")) mstat(FE, label("2-digit Product Fixed Effects")) stars(0.05 "**") showstars showstarsnote title("Table 2A. Baseline Regressions: Probit and ivprobit; Dependent Variable: Tariff Dummy where 1 indicates product is tariffed and 0 otherwise") column(estimates) keep (list_CHN_1 list_CHN_2 list_CHN_3 list_CHN_4 BEC_new different_con change_2011_2015_unweighted weighted_trade_balance_broad) note("Note: 2-digit Product Fixed Effects are included in both models.") note(For IV regression, list_CHN_* is instrumented with China Shock variable.) note(list_CHN_* is a product of listtime dummies for that specific list and list_proposed_CHN_divide.) note(Standard errors are provided in the parentheses.) export(mydoc1a.docx, replace)

The output of the etable is shown below. I will greatly appreciate the reasoning of this is expected or some way to resolve this given it is an issue. Thanks in advance.

[Jeff Pitblado (StataCorp)]

Add option showeq to see that these extra estimates are coefficients for the endogenous variables. Your example names all these coefficients in the keep() option.

Using an example from the documentation, here is how you can use the collect suite of commands to restrict the reported coefficients to the first equation.

webuse laborsup

probit fem_work fem_educ kids other_inc
est store Probit

ivprobit fem_work fem_educ kids (other_inc = male_educ)
est store IVProbit

etable, estimates(Probit IVProbit) column(estimates)

* get the dimensions used in the layout specification
collect layout
* look at the levels of the column equations
collect levels coleq
* restruct to the column equation of interest
collect style autolevels coleq fem_work, clear

collect preview

Here is the resulting table.

---------------------------------------
                        Probit IVProbit
---------------------------------------
Female education level   0.218    0.211
                       (0.027)  (0.027)
Number of children      -0.206   -0.182
                       (0.047)  (0.048)
Other income            -0.038   -0.054
                       (0.004)  (0.006)
Intercept               -0.466    0.367
                       (0.339)  (0.448)
Number of observations     500      500
---------------------------------------

[Preety Bhogal]

Thank you Jeff Pitblado (StataCorp) for explaining this so well. I am able to restrict the table to the coefficients of interest. Does this happen only in case of ivprobit? I did not experience this while running other regressions such as probit, ivreg2, etc.