AS-Thompson (Arcsine) test

[jemima spencer]

Hi,

I've done a meta-analysis of relative receipt of a cardiac intervention (PCI) between people with and without kidney disease ie a binary outcome as an OR. I've drawn some funnel plots to look qualitatively at potential small study size effects and wasn't planning to use a quantitative test as a) there is marked heterogeneity between effect estimates and I have only 20(ish) studies in the meta-analysis and b) the variance estimator of the logOR is statistically dependent on the estimated log OR so most tests will be anti-conservative.

I've now read that the arscine transformation is the best option, and a reasonable one, for this form of data - specifically the AS-Thompson test.

I can't however find any information on how to do the AS-Thompson test using STATA and wondered if anyone might point me in the right direction.

Unclear what data might be helpful for advice re this, so I haven't added anything for now but of course can do (with suggestions please!).

Thanks so much/apologies if the above is rubbish(!)

[Nick Cox]

I don't know anything about this specific literature.

The transformation I think you're talking about was IIRC called the angular transformation by Fisher. The name arcsine seems very common but is inexact if the first step is taking a square root. The original context for this transformation was people facing (0, 1) binary variables.

As Stata's arcsine function, like most if not all such routines, returns an answer in radians, I incline towards using a pre-factor to map back to the same interval, but that could divide opinion.

My single small point is that this transformation does not make much difference unless you have many values very near 0 or very near 1. Mind you, you could say much the same about the logit -- although that is a much stronger transformation and can't cope with exact zeros or ones.

twoway function (2 / _pi) * asin(sqrt(x)), aspect(1) ytitle(Angular transformation) xtitle(Probability)

[Nick Cox]

https://onlinelibrary.wiley.com/doi/....1002/hsr2.178 leads to some literature.

[Tiago Pereira]

Complementing Nick's useful suggestion on the literature.

In Stata, we can use -regress- to implement the AS-Thompson (arcsine) test.

* Example generated by -dataex-. For more info, type help dataex
clear
input str12 author int year double(a b c d)
"Fletcher"     1959   1   11    4    7
"Dewar"        1963   4   17    7   14
"Lippschutz"   1965   6   37    7   34
"European 1"   1969  20   63   15   69
"European 2"   1971  69  304   94  263
"Heikinheimo"  1971  22  197   17  190
"Italian"      1971  19  145   18  139
"Australian 1" 1973  26  238   32  221
"Frankfurt 2"  1973  13   89   29   75
"Gormsen"      1973   2   12    3   11
end

    *! proportion of participants in the treatment and control groups
    gene pt = a/(a+b)
    gene pc = c/(c+d)
    
    *! total sample sizes for the treatment and control groups
    gene nt = a+b
    gene nc = c+d
    *! effect size (arcsin difference) and its variance
    gene es = asin(sqrt(pt))-asin(sqrt(pc))
    gene var_es = (1/(4*nt))+(1/(4*nc))
    
    *! standard error (regressor, called bias here to facilitate interpretation)
    gene bias = sqrt(var_es)
    
    *! Arcsine test (based on linear regression)
    regress es bias [aw=1/var_es]
    lincom bias

The P-value is the one associated with the regressor "bias".

Reference:
Rücker G, Schwarzer G, Carpenter J. Arcsine test for publication bias in meta‐analyses with binary outcomes. Statistics in medicine. 2008 Feb 28;27(5):746-63.

[jemima spencer]

Oh thankyou SO much both of you. Really kind. Will have a go now.