Adding a multiplication of dummy variables into model

[Ahmet Alkan]

Hi,

I apologize if this is a basic question—I’m new to econometrics and Stata, and I really appreciate your guidance.

I would like to add a multiplication of two binary variables into my regression model. How can I do this in Stata?

Thank you for your time and effort!

[Rich Goldstein]

help fvvarlist

and please read the FAQ and follow its advice on asking questions

[George Ford]

As Rich suggests, worth reading the fvvarlist help.

clear all

set obs 1000
g dum1 = runiform()>0.7
g dum2 = runiform()>0.8

g y = 1 + 2*dum1 - 1*dum2 + 0.5*dum1*dum2 + rnormal(0, .1)

reg y dum1 dum2 c.dum1#c.dum2

summ dum1
local m1 = r(mean)
summ dum2
local m2 = r(mean)
reg y c.dum1##c.dum2
margins, dydx(dum1 dum2) atmeans
di _b[dum1] + _b[c.dum1#c.dum2]*`m2'
di _b[dum2] + _b[c.dum1#c.dum2]*`m1'

margins, over(dum1 dum2) atmeans
di _b[_cons] 
di _b[_cons] + _b[dum2] 
di _b[_cons] + _b[dum1] 
di _b[_cons] + _b[dum1] + _b[dum2] + _b[c.dum1#c.dum2]

reg y dum1#dum2
qui reg y c.dum1##c.dum2
di _b[dum2] 
di _b[dum1] 
di _b[dum1] + _b[dum2] + _b[c.dum1#c.dum2]
di _b[_cons] 2
reg y dum1#dum2