Export results from misstable sum to excel

[Katrina Blindow]

Hi! I need to save the results from misstable sum in excel. Should not be too hard, but so far, I got only an empty excel sheet or error messages. Thanks in advance for helpful code.

[Clyde Schechter]

clear*

//    CREATE DEMONSTRATION DATA SET
cd "C:/Users/Clyde/Documents/Sandbox"
sysuse auto
set seed 1234
foreach v of varlist mpg headroom length {
    replace `v' = . if runiform() < 0.1
}

//    SOLVE THE PROBLEM
frame create results str32 varname `c(obs_t)' (eq_dot gt_dot lt_dot ///
    n_distinct minimum maximum)
    
ds, has(type numeric)
foreach v of varlist `r(varlist)' {
    misstable summ `v'
    if !missing(r(N_eq_dot), r(N_gt_dot)) {
        frame post results ("`v'") (r(N_eq_dot)) (r(N_gt_dot)) (r(N_lt_dot)) ///
            (r(K_uniq)) (r(min)) (r(max))
    }
}

frame change results
label var varname "Variable"
label var eq_dot "Obs=."
label var gt_dot "Obs>."
label var lt_dot "Obs<."
label var n_distinct "Unique values"
label var minimum "Min"
label var maximum "Max"

export excel using misstable.xlsx, firstrow(varlabels) replace

[Katrina Blindow]

YES! Thank you