Overlapping map

[Tessa May]

Hi,

I have the first map and I want to outline with with a different color the municipalities in the center (identified with the variable coastal). When I try to do that I get the second map. I am using the following code:

spmap hom1 using "coords.dta", id(id) fcolor("`colors'") ocolor(white ..) ///
osize(0.05 ..) clmethod(custom) clbreaks(0 1 5 15 50 100 200 400) ///
legend(pos(5) size(1.8) region(fcolor(gs15)))

preserve

keep if coastal==2

rename id _ID
keep _ID

merge 1:m _ID using "coords.dta"

keep if _merge==3

save coords2.dta, replace

restore

spmap hom1 using "coords.dta", id(id) fcolor("`colors'") ocolor(white ..) ///
osize(0.05 ..) clmethod(custom) clbreaks(0 1 5 15 50 100 200 400) ///
legend(pos(5) size(1.8) region(fcolor(gs15))) ///
polygon(data("coords2.dta") ocolor(maroon) osize(.1))

Thanks,

Tessa

[Justin Niakamal]

The issue is your coordinates file. The sort order is getting jumbled after the merge. I suggest you use spshape2dta to create the coordinates file and sort on _ID and shape_order. Note: spmap is from SSC. Here's a worked example with a random selection that shows the issue and solution.

copy "https://www2.census.gov/geo/tiger/TIGER2024/COUSUB/tl_2024_06_cousub.zip" ., replace
unzipfile tl_2024_06_cousub.zip
spshape2dta tl_2024_06_cousub, replace

use tl_2024_06_cousub in 1/50, clear
merge 1:m _ID using tl_2024_06_cousub_shp, keep(matched) nogen  
save selected.dta, replace

use tl_2024_06_cousub, clear
spmap using tl_2024_06_cousub_shp.dta, id(_ID) polygon(data(selected.dta) ocolor(red)) title("Not wanted") name(not_sort, replace)

use tl_2024_06_cousub in 1/50, clear
merge 1:m _ID using tl_2024_06_cousub_shp, keep(matched) nogen
sort _ID shape_order 
save selected.dta, replace

use tl_2024_06_cousub, clear
spmap using tl_2024_06_cousub_shp.dta, id(_ID) polygon(data(selected.dta) ocolor(red)) title("Wanted") name(IS_sorted, replace)
gr combine IS_sorted not_sort

Result:

[Tessa May]

Thanks Justin, when I do that i get the following map. Is not quite what I need because I just want the municipalities to be overlined and here they are colored.

I just added after the merge the following:

sort _ID _X _Y

Those are the variables in my coordinates file.

Thanks.

[Justin Niakamal]

sort _ID _X _Y

That will not solve the issue. I suggested you use spshape2dta because it has a shape_order variable, but I suspect you're using shp2dta (SSC). You need to add a sort variable to your coordinates file. Your code above has the coordinates sorted within each polygon _ID.

use coords.dta, clear
gen `c(obs_t)'  id_sort = _n
save coords_sort_id.dta, replace 

preserve

keep if coastal==2

rename id _ID
keep _ID

merge 1:m _ID using "coords_sort_id.dta"
keep if _merge==3
sort  id_sort

save coords2.dta, replace

restore

[Tessa May]

You are right! I decided to use spshape2dta and just adding the sort _ID shape_order worked perfectly.

Thanks,

Tessa