Add prefix to all variables except one (or two)

[Dakota McAvoy]

Let's say I had a dataset with 100 variables, and I wanted to add a prefix (let's say "use_") to all variables except one or two of them. What would be the easiest way to do that other than simply creating a varlist with all 98 variables listed out?

[Joseph Coveney]

version 18.0

quietly sysuse auto, clear

*
* Begin here
*
quietly ds _all
local varlist `r(varlist)'

local exclude rep78 gear_ratio
local varlist : list varlist - exclude

rename (`varlist') use_=

exit

[Joseph Coveney]

What would be the easiest way to do that other than simply creating a varlist with all 98 variables listed out?

You''re not going to be able to avoid traversing the list of ninety-eight variable names in some manner, but you could do something like the following that disguises that.

quietly sysuse autos, clear

foreach var of varlist _all {
    if inlist("`var'", "rep78", "gear_ratio") continue
    rename `var' use_`var'
}

exit

[Nick Cox]

Here's a more direct way to do it, building on Joseph Coveney 's very helpful example:

sysuse auto, clear

ds rep78 gear_ratio, not

rename (`r(varlist)') use_=

ds use_*

Clearly you already have your dataset and just need to change rep78 gear_ratio to the one or two names you wish to exclude.