Add country names to a loop (panel data)

[Anass Wajib]

Hello,

I'm working with a panel data (210 countries) and I'm trying to draw for each country its own name. I got some assistance working out a loop but I wanted to add the countries names on each graph. I did create 'countryid' column to assign each country a specific number but I don't how to add the names on each graph.

Here's the command I'm using.

forvalues i = 1/210 {
    
    tsline cycle trd if countryid == `i' & year >= 1985 & year <= 2020, legend(off)
    
    graph save "Graph" "`i'.gph", replace
    graph export "`i'.jpg", as(jpg) name("Graph") quality(90) replace
}

Thank you in advance.

Edit: added the proper layout for my code

[Andrew Musau]

If you have a variable containing the country names (named "countryname" below):

forvalues i = 1/210 {
    levelsof countryname if countryid==`i', local(name)
    tsline cycle trd if countryid == `i' & year >= 1985 & year <= 2020, legend(off) title("`name'")

[Anass Wajib]

Andrew Musau Thank you for your input but I didn't work out for me.

Here's my code (I replaced countryname with a country column since it has the name of the countries)

forvalues i = 1/210 {
    levelsof country if countryid==`i', local(name)
    tsline cycle trd if countryid == `i' & year >= 1985 & year <= 2020, legend(off) title("`name'")
}

plus it ives me this error r(132) that reads: too few quotes

[Andrew Musau]

Probably you have compound double quotes because of spaces in the country names. Use the -clean- option of levelsof or exclude the double quotes in the -title()- option of tsline.

forvalues i = 1/210 {
    levelsof country if countryid==`i', local(name) clean
    tsline cycle trd if countryid == `i' & year >= 1985 & year <= 2020, legend(off) title("`name'")
}

[Anass Wajib]

Andrew Musau Thank you very much! It worked. Thank you for your time.