Creating Panel Data on Stata

[Melody Brown]

Hi there,

I have a couple of individuals and I want to create a daily panel data structure for these individuals based on the starting date and end date. I wonder if anyone knows how to do this in Stata?

----------------------- copy starting from the next line -----------------------

* Example generated by -dataex-. To install: ssc install dataex
clear
input str23 var1 str11(var2 var3)
"A" "Jan-01-2020" "Jul-01-2020"
"B" "Feb-01-2021" "Aug-01-2021"
"C" "Jan-03-2019" "Mar-07-2019"
end

------------------ copy up to and including the previous line ------------------


Thanks and looking forward to your reply!

Best wishes
Meng

[Clyde Schechter]

gen start = daily(var2, "MDY")
assert !missing(start)
format start %td
drop var2

gen finish = daily(var3, "MDY")
assert !missing(finish)
format finish %td
drop var3

gen expander = finish - start + 1
expand expander
by var1, sort: gen date = start + _n - 1
format date %td
drop expander

[Melody Brown]

gen start = daily(var2, "MDY")
assert !missing(start)
format start %td
drop var2

gen finish = daily(var3, "MDY")
assert !missing(finish)
format finish %td
drop var3

gen expander = finish - start + 1
expand expander
by var1, sort: gen date = start + _n - 1
format date %td
drop expander

Hi Clyde,

The code works perfectly for me. Thanks a lot for your help!