Generating an Event Study Graph

[Netane Ben-Porath]

Hello,

I have balanced panel data of States in the Time 0-10, an outcome variable Y, and a treatment variable Treat. A shock hits all states in Time=5. I want to estimate the effect of the shock interacted with Treat.
To do that I estimate the following Two-Way-Fixed-Effect Event-Study specification:

xtset State
xtreg Y b4.Time##c.Treat, fe robust

I want to present the results graphically. On the X-axis there should be Time 0-10. On the Y-axis there should be the coefficients of the Interaction of Treat and each Year dummy, with the corresponding confidence interval.

I am unsure how I can create this plot. My main problem is that I do not know how to extract and store the coefficients and CIs of the interaction variables.

I would very much appreciate help with this.
Thank you very much.

[Andrew Musau]

ssc install coefplot, replace

webuse grunfeld, clear
xtset company time
xtreg invest ib20.time##c.mvalue, fe robust
set scheme s1mono
coefplot ., keep(*.time#c.mvalue) xlab(1/19) vert  ytitle(Coefficient)

Res.:

[Netane Ben-Porath]

Thank you very much, that is very helpful!
Just two issues arise.
1. The coefficient for Time 4 (the baseline) is dropped, though I would like to include it as coefficient = 0 (with no CI). Can I do this?
2. Relatedly, I would like to add a vertical line at Time 5, signifying the start of the shock. Could I do this?

Thank you very much again.

[Andrew Musau]

The vertical line will interfere with the CI on T=5, but here is how you would do it:

webuse grunfeld, clear
keep if time<11
xtset company time
xtreg invest ib4.time##c.mvalue, fe robust
set scheme s1mono
coefplot ., baselevels omitted xline(5) keep(*.time#c.mvalue) xlab(1/10) vert  ytitle(Coefficient)

[Netane Ben-Porath]

Thank you so much, the omitted coefficient shows perfectly now.

However, the vertical line still does not appear. I think it is because the coefficient is not of Time=5, but rather the interaction of Time=5 with the c.Treat.
But when I try to replace xline(5) with xline(5.Time#c.Treat) I still get an error message.

Thank you again.

[Andrew Musau]

As far as I know, 5 represents the position of the coefficient in the graph. So in my graph, the base is at position 4 and T=5 is at position 5. You will have to present a reproducible example if you are not able to make progress. Also, make sure you have the most up to date version of coefplot.

[Netane Ben-Porath]

Andrew, thank you so much, I was now able to include the xline with no problem.
A final question if I may, can I rename the variables at the X axis? Namely, instead of seeing time#treat, I would just like to see the time at the x-axis.

[Andrew Musau]

webuse grunfeld, clear
keep if time<11
xtset company time
xtreg invest ib4.time##c.mvalue, fe robust
set scheme s1mono
coefplot ., baselevels omitted keep(*.time#c.mvalue)  xtitle(Coefficient)  rename(#c.mvalue = \1, regex)
*OR
coefplot ., baselevels omitted keep(*.time#c.mvalue)  xtitle(Coefficient)  rename(.time#c.mvalue = \1, regex)

[Mateus Maciel]

Dear Andrew Musau, would you mind helping me with a similar issue? I am running the following model:

xtreg tarifa treat##treated treat treated, fe robust cluster(id)

I want to obtain the value of the interaction by year (ano, in my dataset). Thus, I would have to run something like this:

coefplot ., keep(*.ano#treat#treated) xlab(1/12) vert  ytitle(Coefficient)

But I keep getting the following error message:

. coefplot ., keep(*.ano#treat#treated) xlab(1/12) vert  ytitle(Coefficient)
(.: no coefficients found, all dropped, or none kept)
(nothing to plot)

[Andrew Musau]

You don't have a variable "ano" in the regression that you show. Instead of "treat" and "treated", define one indicator "treatment" = 1 if unit \(i\) at time \(t\) was subject to the treatment, and zero otherwise. Then you can interact this indicator with your time variable.

xtreg tarifa c.treatment##i.ano, fe robust cluster(id)

[Mateus Maciel]

Thanks! It worked.