Problems with bootstrap

[Matthias Pierce]

Hi, i am trying to find bootstrap CI's for an estimate, but i can't get it to work. I get a red 'X' for each bootstrap sample. It seems to have something to do with using 'predict' in my programme.

Here is some dummy code (mine is much longer, but this illustrates the problem):


set seed 1010
*Creating dummy data
clear
set obs 1000
gen x = rnormal()
gen e = rnormal()
gen y = e + x

*Programme for bootstrap
capture prog drop btest
prog def btest, rclass

regress y x

predict pr
summ pr

return scalar est = `r(mean)'

end

*bootstrap command
bootstrap r(est), reps(50): btest





Any help very much appreciated!

[Felix Bittmann]

set seed 1010
*Creating dummy data
clear
set obs 1000
gen x = rnormal()
gen e = rnormal()
gen y = e + x

*Programme for bootstrap
capture prog drop btest
prog def btest, rclass

regress y x
cap drop pr
predict pr
summ pr
return scalar est = `r(mean)'
drop pr

end

*bootstrap command
bootstrap r(est), reps(50): btest

[Matthias Pierce]

Works a treat, for some reason i thought that no new variables were retained between bsamples, but good to know - thanks a million!

Matthias