Two different regressions side by side

[Lisa Reiche]

Hello everybody,
I would like to create the following output table.

	y1		y2
x1	Coef.	x4	Coef.
x2	Coef.	x5	Coef.
x3	Coef.	x6	Coef.

It is based on the following regressions:

y1=x1+x2+x3
y2=x4+x5+x6

Even though they are different regressions, they should be right next to each other in the output table.

Can someone tell me how to create it?

Thanks in advance.

Kind regards,
Lisa

[Ken Chui]

Hello, and welcome to Statalist.

This is not an answer on how to achieve that, but rather a recommendation against it, because it's not aligned with the best practice of table making. Chance is that a good portion of the readers will not be aware of the new row title in the middle, causing a lot of confusion. This is a clearer design:

Variable	Model 1	Model 2
x1	Coef	-
x2	Coef	-
x3	Coef	-
x4	-	Coef
x5	-	Coef
x6	-	Coef

And if the two regression are so different, then there is really no reason to tabulate them together, try break them into two tables.

[Lisa Reiche]

Thank you for your reply.

I had already thought about your suggestion but with my object of investigation it would be already to compare the coefficients. I examine the CEO turnover (y1) and the CFO turnover (y2). A dependent variable is in each case e.g. CEO age (x1) and CFO age (x4). And I would like to present in a way that a comparison is very easy. Would you have an alternative suggestion?

[Andrew Musau]

The easiest way that avoids complications is to rename the variables prior to the regressions. The following uses estout from SSC. In the auto dataset, suppose that I use weight and price, respectively to proxy size and quality in one regression and length and repair record, respectively, in another regression. My models are:

\(Mileage_i= \beta_1+ \beta_2\;weight_i+ \beta_3\;price_i + u_{1i}\)
\(Mileage_i= \beta_4+ \beta_5\;length_i+ \beta_6\;repair\;record_i + u_{2i}\)

where the subscript \(i\) indexes cars. Direct estimation and combining the results results in:

sysuse auto, clear
eststo m1: regress mpg weight price, robust
eststo m2: regress mpg length rep78, robust
esttab m1 m2, label

Res.:

. esttab m1 m2, label

----------------------------------------------------
                              (1)             (2)  
                     Mileage (m~)    Mileage (m~)  
----------------------------------------------------
Weight (lbs.)            -0.00582***                
                          (-8.91)                  

Price                  -0.0000935                  
                          (-0.53)                  

Length (in.)                               -0.195***
                                         (-10.61)  

Repair Record 1978                          0.767  
                                           (1.37)  

Constant                    39.44***        55.44***
                          (19.56)         (13.66)  
----------------------------------------------------
Observations                   74              69  
----------------------------------------------------
t statistics in parentheses
* p<0.05, ** p<0.01, *** p<0.001

.

and renaming variables results in:

sysuse auto, clear
cap rename (weight price) (size quality) 
eststo m3: regress mpg size quality, robust
cap rename (size quality)  (weight price)
cap rename (length rep78) (size quality) 
eststo m4: regress mpg size quality, robust
cap rename (size quality) (length rep78) 
esttab m3 m4, label coeflabels(size "Size" quality "Quality")

Res.:

. esttab m3 m4, label coeflabels(size "Size" quality "Quality")

----------------------------------------------------
                              (1)             (2)  
                     Mileage (m~)    Mileage (m~)  
----------------------------------------------------
Size                     -0.00582***       -0.195***
                          (-8.91)        (-10.61)  

Quality                -0.0000935           0.767  
                          (-0.53)          (1.37)  

Constant                    39.44***        55.44***
                          (19.56)         (13.66)  
----------------------------------------------------
Observations                   74              69  
----------------------------------------------------
t statistics in parentheses
* p<0.05, ** p<0.01, *** p<0.001

.