What is the best program to generate heat maps in Stata?

[Tiago Pereira]

Dear Statalisters,

I have tried hmap, heatplot and corrtable. They are all amazing programs, but I could not figure out how to obtain the results we need.

Let me be more specific:

I have data like this:

 clear all
   set obs 64
   g n=int(uniform()*10)
   g x=1+int((_n-1)/8)
   g y=1+mod((_n-1),8)
   la def xlab 1 "one" 2 "two" 7 "seven" 8 "eight"
   la def ylab 3 "three" 4 "four" 5 "five" 6 "six"
   la val x xlab
   la val y ylab
   ta y x [fw=n]
   label define test 9 "good"  8 "mild"
   label values n test
   hmap x y n
   hmap x y n, sc

And I need the following features:

• Plot labels, not numbers in the variable called "n" (hmap does that)
• Be able to specify colors. For example, if n > 7 & n <9 the color should be green, if n == 2 the color should be blue, etc.
• Put the horizontal axis/stick at the top

Any suggestions or tips?

All the best,

Tiago

[Andrew Musau]

It may be easier to program this in twoway rather than trying to figure out the options in the community-contributed commands. Here is how I would do it.

clear all
   set obs 64
   g n=int(uniform()*10)
   g x=1+int((_n-1)/8)
   g y=1+mod((_n-1),8)
   la def xlab 1 "one" 2 "two" 7 "seven" 8 "eight"
   la def ylab 3 "three" 4 "four" 5 "five" 6 "six"
   la val x xlab
   la val y ylab
   ta y x [fw=n]
   label define test 9 "good"  8 "mild"
   label values n test

decode n, gen(lab)
replace lab= "" if !missing(real(lab))
gen xl= x-0.5
 quietly: summarize y
    local count = `r(max)' 
    local xlab
    forval i=1/`count'{
        local xlab "`xlab' `=`i'-0.5' `" "`:lab (x) `i''" "'"
    } 

gen start= y-1
tw (rbar start y x if n==2, horiz barw(0.9) lc(white) fc(blue)  xsc(alt) ///
ylab(1/8, val)  xlab(`xlab')) (rbar start y x if inrange(n, 7, 9), horiz ///
barw(0.9) lc(white) fc(green)) (rbar start y x if (!inrange(n, 7, 9)|n!=2), ///
horiz barw(0.9) lc(white) fc(navy%40)) (scatter y xl, mc(none) ///
mlab(lab) mlabc(black) mlabpos(0) leg(off) scheme(s1mono))

[John Mullahy]

As always Andrew offers an elegant and useful solution. It is a matter of taste, I suppose, but you might consider adding the option

aspect(1)

to Andrew's option list. The rectangles will look more like squares with this option.

[Tiago Pereira]

As always, thank you very much, Andrew. Extremely helpful suggestion. Very easy to adapt the final code based on your initial code. Thanks, John, for the question about the option aspect(1.0). It improves the visual appeal of the graph.