Multiple subgroup meta-analysis

[Adolfo Aramburu]

Good evening, I want to do a meta-analysis of multiple subgroups.

* Example generated by -dataex-. For more info, type help dataex
clear
input str50 studyid float(fm_event_n fm_event_tot fm_nonevent_n cont_event_n cont_event_tot cont_nonevent_n days_therapy type_therapy probiotic_sp)
"Bekar 2011"                                     36  46 10  18  36 18 2 1 .
"Deguchi 2012 (antibiotic-resistant)"            10  26 16   7  25 18 1 1 1
"Deguchi 2012 (antibiotic susceptible)"          65  70  5  58  67  9 1 1 1
"Guillemard 2021"                                57  68 11  60  68  8 2 2 2
"Kim 2008 (with nonulcer dyspepsia)"             87 113 26  88 121 33 1 1 2
"Kim 2008 (with peptic ulcer disease)"           46  55  9  41  58 17 1 1 2
"Mirzaee y Rezahosseini 2012 (without placebo)"  20  31 11  19  26  7 1 1 .
"Mirzaee y Rezahosseini 2012 (with placebo)"     19  31 12  19  26  7 1 1 .
"Sheu 2002"                                      73  80  7  63  80 17 1 1 2
"Srinarong 2014 (14-day therapy)"                25  25  0  24  25  1 2 2 2
"Srinarong 2014 (7-day therapy)"                 25  25  0  23  25  2 1 2 2
"Yasar 2010"                                     25  38 13  20  38 18 2 1 1
"Yoon 2010"                                     104 151 47 124 186 62 2 1 2
end
label values days_therapy days_therapy
label def days_therapy 1 "Seven days", modify
label def days_therapy 2 "Fourteen days", modify
label values type_therapy type_therapy
label def type_therapy 1 "Triple therapy", modify
label def type_therapy 2 "Quadruple therapy", modify
label values probiotic_sp probiotic_sp
label def probiotic_sp 1 "Single", modify
label def probiotic_sp 2 "Multiple", modify

I have tried the following syntax:

meta esize fm_event_n fm_nonevent_n cont_event_n cont_nonevent_n, esize(lnrratio) random(dlaird) studylabel(studyid)
meta summarize, eform(Risk ratio)
meta forestplot, subgroup(days_therapy type_therapy probiotic_sp) eform(Risk ratio) nullrefline(favorsleft("Favors control") favorsright("Favors Milk fermented")) columnopts(_K, title(Number of studies)) nooverall nogbhomtests noohomtest noohetstats nonotes

The problem is that all the subgroups have information from 13 studies, but one of them (probiotic_sp) only has information from 10 studies. When doing the meta-analysis, all the subgroups came out with only 10 studies. I appreciate any advice to solve this problem.

Thanks

[Jared Greathouse]

The missing data seems to be the issue here.

[Adolfo Aramburu]

Thanks Jared, I agree that the problems stem from missing values. I don't know if there is any way that the general analysis is not affected by the missing of one of the variables.

[Jared Greathouse]

Adolfo Aramburu Are these missing moderators? That is, when you were coding these papers, did you ultimately not know how to classify these and left them missing?

[Adolfo Aramburu]

Hi Jared. No, the clinical trials did not report information on the probiotic species (variable probiotic_sp) in the fermented milk. The only thing I can think of is to code these missing as "not reported" and report them as a third category (single, multiple, and "not reported"), although I would rather not include it if there is some way to limit it in the Stata code.

[Jared Greathouse]

Adolfo Aramburu From one meta-analyst to another, you wanna code these as not reported.

[Adolfo Aramburu]

I would like to generate a forest plot similar to this one, but without considering the category "Non reported" in Probiotic species (which I have had to generate so that the other subgroups can have information from the 13 studies).

[Jared Greathouse]

Better? Adolfo Aramburu

* Example generated by -dataex-. For more info, type help dataex
clear
input str50 studyid float(fm_event_n fm_event_tot fm_nonevent_n cont_event_n cont_event_tot cont_nonevent_n days_therapy type_therapy probiotic_sp)
"Bekar 2011"                                     36  46 10  18  36 18 2 1 .
"Deguchi 2012 (antibiotic-resistant)"            10  26 16   7  25 18 1 1 1
"Deguchi 2012 (antibiotic susceptible)"          65  70  5  58  67  9 1 1 1
"Guillemard 2021"                                57  68 11  60  68  8 2 2 2
"Kim 2008 (with nonulcer dyspepsia)"             87 113 26  88 121 33 1 1 2
"Kim 2008 (with peptic ulcer disease)"           46  55  9  41  58 17 1 1 2
"Mirzaee y Rezahosseini 2012 (without placebo)"  20  31 11  19  26  7 1 1 .
"Mirzaee y Rezahosseini 2012 (with placebo)"     19  31 12  19  26  7 1 1 .
"Sheu 2002"                                      73  80  7  63  80 17 1 1 2
"Srinarong 2014 (14-day therapy)"                25  25  0  24  25  1 2 2 2
"Srinarong 2014 (7-day therapy)"                 25  25  0  23  25  2 1 2 2
"Yasar 2010"                                     25  38 13  20  38 18 2 1 1
"Yoon 2010"                                     104 151 47 124 186 62 2 1 2
end
label values days_therapy days_therapy
label def days_therapy 1 "Seven days", modify
label def days_therapy 2 "Fourteen days", modify
label values type_therapy type_therapy
label def type_therapy 1 "Triple therapy", modify
label def type_therapy 2 "Quadruple therapy", modify
label values probiotic_sp probiotic_sp
label def probiotic_sp 1 "Single", modify
label def probiotic_sp 2 "Multiple", modify

meta esize fm_event_n fm_nonevent_n cont_event_n cont_nonevent_n, esize(lnrratio) random(dlaird) studylabel(studyid)
meta summarize, eform(Risk ratio)
meta forestplot if !mi(probiotic_sp), subgroup(days_therapy type_therapy probiotic_sp) eform(Risk ratio) nullrefline(favorsleft("Favors control") favorsright("Favors Milk fermented")) columnopts(_K, title(Number of studies)) nooverall nogbhomtests noohomtest noohetstats nonotes

[David Fisher]

What about simply replacing the missing values with a non-missing value (say "9") and labelling as "Missing" ?

replace probiotic_sp = 9 if missing(probiotic_sp)
label def probiotic_sp 9 "Missing", modify

meta esize fm_event_n fm_nonevent_n cont_event_n cont_nonevent_n, esize(lnrratio) random(dlaird) studylabel(studyid)
meta summarize, eform(Risk ratio)
meta forestplot , subgroup(days_therapy type_therapy probiotic_sp) eform(Risk ratio) nullrefline(favorsleft("Favors control") favorsright("Favors Milk fermented")) columnopts(_K, title(Number of studies)) nooverall nogbhomtests noohomtest noohetstats nonotes

[Adolfo Aramburu]

The idea was to generate a graph where only valid data was reported. But when including 'Probiotic species' (where only 10 of 13 studies report results), all other subgroups (which have information from 13 studies) are reported as if they were 10 studies. The result should look something like this (edited graph), note that all subgroups have 13 studies, except "Probiotic species" which has 10.

I can't find a code that allows me to make this graph correctly. So I have decided to consider a category of "Not reported" in "Probiotic species" for the forest plot to report results from all 13 studies.

Thank you for your answers.