question about heatplot?

[Raymond Zhang]

Dear all, I want to use heatplot command to plot correlation coefficients graph.
here is the example code.Can I add significance level for displaying with a star(* ** ***) to the graph?

. quietly sysuse auto, clear
. quietly correlate price mpg trunk weight length turn foreign
. matrix C = r(C)
. heatplot C, values(format(%9.3f)) color(hcl, diverging intensity(.6)) ///
  legend(off) aspectratio(1) lower

[Raymond Zhang]

@Ben Jann

[Raymond Zhang]

I want to add stars to show the significance level. just like the graph below,

[Ben Jann]

This cannot be done directly, but here's a (somewhat involved) workaround using two calls to heatplot:

sysuse auto, clear
// compute correlations and p-values
pwcorr price mpg trunk weight length turn foreign, sig
matrix C = r(C)
matrix sig = r(sig)
// apply heatplot without displaying a graph, just to collect information;
// option generate stores the information (coordinates etc) as variables
heatplot C, values(label(sig)) lower nodraw generate
// generate a new variable containing the text for the labels; the correlations
// have been stored in variable _Z, the p-values in variable _Mlab
gen str lab = string(_Z, "%9.2f") + ///
    cond(_Mlab<.001, "***", cond(_Mlab<.01, "**", cond(_Mlab<.1, "*", "")))
// second call to heatplot useing addplot to print the marker labels
heatplot C, color(hcl diverging, intensity(.6)) lower legend(off) aspectratio(1) ///
    addplot(scatter _Y _X, msymbol(i) mlab(lab) mlabpos(0) mlabcolor(black))

Or if you want the stars below the numbers:

sysuse auto, clear
// compute correlations and p-values
pwcorr price mpg trunk weight length turn foreign, sig
matrix C = r(C)
matrix sig = r(sig)
// apply heatplot without displaying a graph, just to collect information;
// option generate stores the information (coordinates etc) as variables
heatplot C, values(label(sig)) lower nodraw generate
// significance stars
gen str sig = cond(_Mlab<.001, "***", cond(_Mlab<.01, "**", cond(_Mlab<.1, "*", "")))
// second call to heatplot useing addplot to print the marker labels
heatplot C, color(hcl diverging, intensity(.6)) lower legend(off) aspectratio(1) ///
    addplot(scatter _Y _X if _Y!=_X, msym(i) mlab(_Z) mlabf(%9.2f) mlabpos(0) mlabc(black) ///
        || scatter _Y _X if _Y==_X, msym(i) mlab(_Z) mlabf(%9.0f) mlabpos(0) mlabc(black) ///
        || scatter _Y _X if _Y!=_X, msym(i) mlab(sig) mlabpos(6) mlabgap(2) mlabc(black))

This example also illustrates how you can use different labels on the diagonal.

[Raymond Zhang]

@Thanks a lot.I find that you have updated heatplot to version 1.0.9. And you have updated the helpfile. After updating the latest version,Now your codes works well.

[Eloise Cameron]

Wondering if this code can show the actual p value under the correlation rather than the stars? I have Stata 17.

[Andrew Musau]

The p-values define the stars, so you may just ask for these values to be displayed directly. You could also change the font size.

sysuse auto, clear
// compute correlations and p-values
pwcorr price mpg trunk weight length turn foreign, sig
matrix C = r(C)
matrix sig = r(sig)
// apply heatplot without displaying a graph, just to collect information;
// option generate stores the information (coordinates etc) as variables
heatplot C, values(label(sig)) lower nodraw generate
// significance stars
gen str sig = cond(_Mlab<.001, "<.001", string(_Mlab, "%4.3f"))
// second call to heatplot useing addplot to print the marker labels
heatplot C, color(hcl diverging, intensity(.6)) lower legend(off) aspectratio(1) ///
    addplot(scatter _Y _X if _Y!=_X, msym(i) mlab(_Z) mlabf(%9.2f) mlabpos(0) mlabc(black) ///
        || scatter _Y _X if _Y==_X, msym(i) mlab(_Z) mlabf(%9.0f) mlabpos(0) mlabc(black) ///
        || scatter _Y _X if _Y!=_X, msym(i) mlab(sig) mlabpos(6) mlabgap(2) mlabc(black) mlabsize(vsmall))

Res.:

[Eloise Cameron]

Thank you, that change worked for me.

[Larry Gill]

This heatplot looks like it fits my use case really well, except that I'm generating a correlation matrix using the "spearman" command with the parameters "stats(rho p)" added to it. Apart from this I'm fairly sure my code is the same as yours Andrew. However, when running the do file I get the error "variable __00000O not found". What could be causing this? I imagine it's an error due to a missing variable but I'm not sure which one it could be

[Larry Gill]

Actually don't worry, got it all sorted now. Needed to use r(Rho) and r(P) instead of r(C) and r(sig).

[Andrew Musau]

Apart from this I'm fairly sure my code is the same as yours Andrew. However, when running the do file I get the error "variable __00000O not found". What could be causing this? I imagine it's an error due to a missing variable but I'm not sure which one it could be

The code in #7 still works for me. Make sure your installation is up to date.

ssc install heatplot, replace

[Larry Gill]

Thanks for the help Andrew, I've got the heatplot displaying but the text is overflowing from each square of it. Is there any way to enlarge/specify the size of the colour squares (or just make the text more of a pretty display generally)?

[Andrew Musau]

There is some space to be recovered by eliminating the plot region margin. But ultimately, something has to give: either reduce the size of the marker labels or the size of the axes labels.

sysuse auto, clear
// compute correlations and p-values
pwcorr price mpg trunk weight length turn foreign, sig
matrix C = r(C)
matrix sig = r(sig)
// apply heatplot without displaying a graph, just to collect information;
// option generate stores the information (coordinates etc) as variables
heatplot C, values(label(sig)) lower nodraw generate
// significance stars
gen str sig = cond(_Mlab<.001, "<.001", string(_Mlab, "%4.3f"))
// second call to heatplot useing addplot to print the marker labels
set scheme s1color
heatplot C, color(hcl diverging, intensity(.6)) lower legend(off) aspectratio(1) ///
    addplot(scatter _Y _X if _Y!=_X, msym(i) mlab(_Z) mlabf(%9.2f) mlabpos(0) mlabc(black) ///
        || scatter _Y _X if _Y==_X, msym(i) mlab(_Z) mlabf(%9.0f) mlabpos(0) mlabc(black) ///
        || scatter _Y _X if _Y!=_X, msym(i) mlab(sig) mlabpos(6) mlabgap(2) mlabc(black) ///
           mlabsize(vsmall) plotregion(margin(zero)))

Res.:

[Andrew Musau]

Is there any way to enlarge/specify the size of the colour squares (or just make the text more of a pretty display generally)?

Here is a suggestion for modifying the axes labels based on the example in #4. To left align the y-axis labels, I alternate the y-axis and move the labels to the LHS, so this will involve manually specifying the label gap.

sysuse auto, clear

*MODIFY LABELS
local ylab
local i 0
foreach var of varlist foreign turn length weight trunk mpg price{
    local ++i  
    local ylab `ylab' `i' "(`i') `var'"  
}


local xlab
local i 0
foreach var of varlist price mpg trunk weight length turn foreign{
local ++i  
    local xlab `xlab' `i' "(`i')"
} 



// compute correlations and p-values
pwcorr price mpg trunk weight length turn foreign, sig
matrix C = r(C)
matrix sig = r(sig)
// apply heatplot without displaying a graph, just to collect information;
// option generate stores the information (coordinates etc) as variables
set scheme s2color
heatplot C, values(label(sig)) lower nodraw generate
// significance stars
gen str sig = cond(_Mlab<.001, "<.001", string(_Mlab, "%4.3f"))
// second call to heatplot useing addplot to print the marker labels
heatplot C, color(hcl diverging, intensity(.6)) lower legend(off) aspectratio(1) ///
    xlab(`xlab', noticks labgap(2)) ylab(`ylab', noticks nogrid labgap(-104)) ///
    yscale(lstyle(none)) xscale(lstyle(none))  plotregion(margin(zero)) ///
    graphregion(color(white)) ysc(alt)  ///
    addplot(scatter _Y _X if _Y!=_X, msym(i) mlab(_Z) mlabf(%9.2f) mlabpos(0) mlabc(black) ///
        || scatter _Y _X if _Y==_X, msym(i) mlab(_Z) mlabf(%9.0f) mlabpos(0) mlabc(black) ///
        || scatter _Y _X if _Y!=_X, msym(i) mlab(sig) mlabpos(6) mlabgap(2) mlabc(black) ///
           mlabsize(vsmall) )

[Juan Vicente-Valor]

Hi. I am not managing to fit all rho and p-values into the heatplot squares (my matrix is very big = 34 x 34), and my font size seems oversized. Is there any way to reduce it with syntax? Option mlabize(vtiny) is not working (it sets it as medium, I think). I have managed to do it with graph editor, but I wondered if label size can be further reduced by means of syntax.

Kind regards,
Juan Vicente
StataIC16