rdplot (part of rdrobust) problem?

[River Huang]

Dear All, This is a related problem as here (https://www.statalist.org/forums/for...ange-in-x-axis). Please search rdrobust and install (SJ-17-2 st0366_1) code/data. The code is

use rdrobust_rdsenate.dta, clear
rdplot vote margin, graph_options(title(RD plot))

and the graph is

Suppose that, for some reason, I just want to show the graph with x-axis ranging from -100 to 50 (not to 100). Any suggestions are highly appreciated.

[Ali Atia]

My suggestion from the other thread still stands - you can just run the regression and plot the graph manually. I don't have access to the rdrobust_rdsenate.dta file, so here's an illustration of the polynomial fit using auto.dta:

clear *
sysuse auto
rdplot mpg weight, graph_options(title(RD plot)) c(2500) genvars
forvalue x=2/4{
    gen weight`x' = weight^`x'
}
reg mpg weight* if weight>=2500
predict yhat1
reg mpg weight* if weight<=2500
predict yhat2
twoway line yhat1 weight if weight>=2500 & weight<3500,sort(weight) lcolor(gs0)|| line yhat2 weight if weight<=2500,sort(weight) lcolor(gs0) || scatter rdplot_mean_y rdplot_mean_x if weight<3500, mcolor(gs7) msymbol(O)||, name(graph3) yla(10(10)40) xline(2500,lcolor(gs0)) title("Non-RD plot") legend(order(1 "Polynomial fit of order 4" 3 "Sample average within bin")) xla(1500(1000)3500)

A comparison of the results:

[River Huang]

Dear Ali, Thanks again. I will give it a try tomorrow.

[Andrew Musau]

You get a discontinuity in the graph in #2 where there is a break. This could be fixed by extending the end-point of the line in the first subgraph. An alternative is to use the original graph's data. For your graph in #1

tempfile s0 s1 s2
forval i=0/2{
    use rdrobust_senate.dta, clear
    qui rdplot vote margin, graph_options(title(RD plot))
    serset `i'
    serset use, clear
    save `s`i''
}
use `s0', clear
merge 1:1 _n using `s1', nogen
merge 1:1 _n using `s2', nogen

twoway (scatter rdplot_mean_y rdplot_mean_bin if rdplot_mean_bin<=50, ///
sort msize(small)  mcolor(gs10)) (line y_plot_l x_plot_l, lcolor(black) sort ///
lwidth(medthin) lpattern(solid)) (line y_plot_r x_plot_r if x_plot_r<=50, lcolor(black) ///
sort lwidth(medthin) lpattern(solid)),  xline(0, lcolor(black) lwidth(medthin)) ///
legend(cols(2) order(2 "Sample average within bin" 3 "Polynomial fit of order 4"))

Res.:

[Raymond Zhang]

@River Huang Here is my sulution.Mm,maybe the graph is a little diferent from rdplot in the left side.

use rdrobust_rdsenate.dta, clear
rdplot vote margin, genvars graph_options(title(RD plot))
twoway (scatter rdplot_mean_y rdplot_mean_x if margin<0,sort mlabsize(small))  ///
       (scatter rdplot_mean_y rdplot_mean_x if inrange(margin,0,50),sort) ///
       (line rdplot_hat_y margin if margin<0 ,sort)  ///
       (line rdplot_hat_y margin if inrange(margin,0,50) ,sort), ///
       xline(0) legend(off) scheme(s1color)

[River Huang]

Dear Andrew, Thanks a lot for this helpful suggestion.

[River Huang]

Dear Raymond, Thanks a lot for this helpful suggestion.