Bar graph conditional formatting

[Yariv Houvras]

Almost totally new at this...

I would like to create a bar graph and apply conditional formatting to select cells in order to change their color.

In the data table below I used:

graph hbar (asis) conditiona conditionb, over(goterm, sort(order))

Now I would like to use the variables pofa, pofb to selectively color bars that fall below certain thresholds.

So for example pathway one, condition b, pofb<0.01 so I would like to set the color of that bar to red, but pathwaytwo, conditionb, pofb>0.01 so that bar would be set to black.

This problem may be trivially easy, but I could not solve it with the available documentation that I found in the manual.

Thanks in advance for any tips!

goterm conditiona conditionb pofa pofb pathwayone 1.2 -2.5 0.1 0.01 pathwaytwo -1.25 -2.49 0.01 0.1 pathwaythree 2.19 -2.42 0.01 0.01

[Andrew Musau]

reshape your data such that you can specify an identifier for your condition.

* Example generated by -dataex-. To install: ssc install dataex
clear
input str15 goterm float(conditiona conditionb pofa pofb)
"pathwayone"     1.2  -2.5  .1 .01
"pathwaytwo"   -1.25 -2.49 .01  .1
"pathwaythree"  2.19 -2.42 .01 .01
end

reshape long condition pof, i(goterm) j(which) string
replace which= cond(which=="a", "condition a", "condition b")
gen group= pof>0.01
seperate condition, by(group)
graph hbar condition?,   over(which) over(goterm) bar(1, color(red)) ///
bar(2, color(black)) leg(off) note("Note: Black bars represent pof>0.01") ///
scheme(s1color)

[Yariv Houvras]

Andrew, this is super helpful! One thing I don't understand is the function of this line in your code:

replace which= cond(which=="a", "condition a", "condition b")
And whether this line is necessary?

[Andrew Musau]

This just changes the label from "a" and "b" to "condition a" and "condition b", respectively. Not necessary for the functioning of the code.

[Yariv Houvras]

Andrew, Thanks so much for lending your expertise. I got your code to work perfectly and it looks great.

Is it possible to preserve the color by which (e.g. blue for one category, green for the other) and apply shading based on the group?

[Andrew Musau]

* Example generated by -dataex-. To install: ssc install dataex
clear
input str15 goterm float(conditiona conditionb pofa pofb)
"pathwayone"     1.2  -2.5  .1 .01
"pathwaytwo"   -1.25 -2.49 .01  .1
"pathwaythree"  2.19 -2.42 .01 .01
end

reshape long condition pof, i(goterm) j(which) string
replace which= cond(which=="a", "condition a", "condition b")
gen group= pof>0.01
egen bygroup= group(group which)
separate condition, by(bygroup)
graph hbar condition?, over(which) over(goterm) bar(1, color(blue)) ///
bar(2, color(green)) bar(3, color(blue%40)) bar(4, color(green%40)) nofill ///
leg(off) note("Note: Light-shaded bars represent pof>0.01") scheme(s1color)

[Yariv Houvras]

so helpful! is it possible to achieve the same ordering as you get here using 'over(which)' but suppress that? I tried setting 'over(which, lab(labsize(zero)))' which is close to what I am looking for, but i want it to be essentially as if there was no over(which) command. the issue is that stata will order the bars based on the magnitude of condition? which is not desirable.

[Andrew Musau]

Then just sort using which, and you will then need a legend. Also note that if you want to adjust intensity without affecting opacity, use color*# instead of color%# as below.

* Example generated by -dataex-. To install: ssc install dataex
clear
input str15 goterm float(conditiona conditionb pofa pofb)
"pathwayone"     1.2  -2.5  .1 .01
"pathwaytwo"   -1.25 -2.49 .01  .1
"pathwaythree"  2.19 -2.42 .01 .01
end

reshape long condition pof, i(goterm) j(which) string
replace which= cond(which=="a", "condition a", "condition b")
gen group= pof>0.01
egen bygroup= group(group which)
separate condition, by(bygroup)
graph hbar condition?, over(goterm, sort(which)) bar(1, color(blue)) ///
bar(2, color(green)) bar(3, color(blue*0.5)) bar(4, color(green*0.5)) nofill ///
leg(order(1 "condition a" 2 "condition b") col(1) ) note("Note: Light-shaded ///
bars represent pof>0.01") scheme(s1color)

[Yariv Houvras]

Andrew, in this example the order of the bars changes by (goterm): so it goes green, blue then blue, green, etc (see .png below)

I don't understand what information Stata is using to pick which bar to list first??

I'd like to have a consistent order, so it always puts blue bar first, for example. In my real dataset I tried creating a new variable and sorted on that, but it still swaps the order for some reason I can't figure out.

[Andrew Musau]

You are right, sorry - I did not pay attention to the rendered graph. It appears that Stata will not sort within over categories, so our best bet is to replicate the wanted graph using the two over variables. Unless I am missing something, the main difference lies in the widths of the bars and spacing between grouped bars, which we can control. Here is another try:

* Example generated by -dataex-. To install: ssc install dataex
clear
input str15 goterm float(conditiona conditionb pofa pofb)
"pathwayone"     1.2  -2.5  .1 .01
"pathwaytwo"   -1.25 -2.49 .01  .1
"pathwaythree"  2.19 -2.42 .01 .01
end

reshape long condition pof, i(goterm) j(which) string
replace which= cond(which=="a", "condition a", "condition b")
gen group= pof>0.01
egen bygroup= group(group which)
separate condition, by(bygroup)
gen order=_n
graph hbar condition?, over(which, lab(nolab) gap(*0)) over(goterm, gap(*0.2)) ///
bar(1, color(blue)) bar(2, color(green)) bar(3, color(blue*0.5)) ///
bar(4, color(green*0.5)) nofill leg(order(1 "condition a" 2 "condition b") ///
col(1) ) note("Note: Light-shaded bars represent pof>0.01") scheme(s1color)

[Yariv Houvras]

I can not thank you enough for your help with this! The expertise and generosity of this group is truly stunning.

[Yariv Houvras]

Hi,

Is it possible to adjust the width of the bars in the graph while keeping the overall dimensions of the graph the same? I can't find a command that will do this for a graph hbar.

For example: I'd like to reduce the width of the bars in the graph above by 50%, is that possible?

Thanks,

Yariv

[Andrew Musau]

Don't you just increase the gap between bars?

* Example generated by -dataex-. To install: ssc install dataex
clear
input str15 goterm float(conditiona conditionb pofa pofb)
"pathwayone"     1.2  -2.5  .1 .01
"pathwaytwo"   -1.25 -2.49 .01  .1
"pathwaythree"  2.19 -2.42 .01 .01
end

reshape long condition pof, i(goterm) j(which) string
replace which= cond(which=="a", "condition a", "condition b")
gen group= pof>0.01
egen bygroup= group(group which)
separate condition, by(bygroup)
gen order=_n
graph hbar condition?, over(which, lab(nolab) gap(*0)) over(goterm, gap(*0.2)) ///
bar(1, color(blue)) bar(2, color(green)) bar(3, color(blue*0.5)) ///
bar(4, color(green*0.5)) nofill leg(order(1 "condition a" 2 "condition b") ///
col(1) ) note("Note: Light-shaded bars represent pof>0.01") scheme(s1color)
gr save gr1, replace
graph hbar condition?, over(which, lab(nolab) gap(*0)) over(goterm, gap(*0.7)) ///
bar(1, color(blue)) bar(2, color(green)) bar(3, color(blue*0.5)) ///
bar(4, color(green*0.5)) nofill leg(order(1 "condition a" 2 "condition b") ///
col(1) ) note("Note: Light-shaded bars represent pof>0.01") scheme(s1color)
gr save gr2, replace
gr combine gr1.gph gr2.gph, scheme(s1color)