Access the actual current date and time from computer clock to input in file name

[Francois Durant]

Hi,

I would like to access the actual current date and time from computer clock to input in file names. I am running multiple simulations per day, I would like to achieve results sorted by date and time under the following format:
save "YYYY-MM-DD-hh:mm-Results.dta"

Is that something Stata can do? Thanks a lot in advance.

[Nick Cox]

. di "$S_DATE $S_TIME"
24 Jul 2020 09:17:39

. local wanted = subinstr("$S_DATE", " ", "_", .) + "_" + "$S_TIME"

. di "`wanted'"
24_Jul_2020_09:19:52

and so on.

[Joro Kolev]

Awesome !

Can you also show us how to put the date and time in what I think they call Hungarian format, e.g., here in this example it would be 20200724091952?

I wanted once to set my seed like this, and either I did not manage to figure it out, or figured it out and then forgot how I did it.

This might be useful for Francois as well, dates in Hungarian format sort very nicely.

. di "$S_DATE $S_TIME"
24 Jul 2020 09:17:39

. local wanted = subinstr("$S_DATE", " ", "_", .) + "_" + "$S_TIME"

. di "`wanted'"
24_Jul_2020_09:19:52

and so on.

[Joseph Coveney]

It's called ISO 8601, as it is the international standard for this, and the international standard allows delimiters, such as "T" between the date and time portions, for improved readability.

. display in smcl as text %tcCCYYNNDD!THHMMSS clock("`c(current_date)'`c(current_time)'", "DMYhms")
20200724T180942

[Francois Durant]

This is truly awesome, thank you so much Nick and Joseph.

Slight modification: Is it possible to avoid displaying seconds in the final output both in ISO 8601 and in the format suggested by Nick? Thanks!

[Nick Cox]

. di substr("$S_TIME", 1, 5)
12:55

[Joseph Coveney]

Is it possible to avoid displaying seconds in the final output both in ISO 8601 and in the format suggested by Nick?

Nick has shown you for his. For the approach that I illustrated with an ISO 8601 format, you'd just forgo the final two esses in the format statement.

. local now : display %tcCCYYNNDDHHMM clock("`c(current_date)'`c(current_time)'", "DMYhms")

. display in smcl as text "`now'"
202007242104

[R Allan Reese]

Another use of dates is for generating an automatic log of activity. In my profile.do is this code for a daily log file. Very useful when someone asks months later how a variable was generated or edited!

local ver = 16 /* could get this automatically */
local logdate = string( d(`c(current_date)'), "%dCY-N-D" )
capture cmdlog using "c:\stata`ver'logfiles\log`logdate'.txt", append