Keeping strings within quotes

[Andrea Cinque]

Dear Stata users,

I have a string variable as the following:

ABC
DEF "XYZ"
GJK "LMN"
PQR
...

I would need to only keep values within "" and those without the quotes, that is:

ABC
XYZ
LMN
PQR
...


Thanks!

[Nick Cox]

I used moss from SSC:

* Example generated by -dataex-. To install: ssc install dataex
clear
input str9 abc
"ABC"        
`"DEF "XYZ""'
`"GJK "LMN""'
"PQR"        
end

moss abc , match("\"(.*)\"") regex
gen wanted = cond(_match1 != "", _match1, abc)
drop _* 
l abc wanted

     +--------------------+
     |       abc   wanted |
     |--------------------|
  1. |       ABC      ABC |
  2. | DEF "XYZ"      XYZ |
  3. | GJK "LMN"      LMN |
  4. |       PQR      PQR |
     +--------------------+

[Andrea Cinque]

Thank you Nick, but it says "_match1 not found"

[Andrea Cinque]

Anyone?

[Nick Cox]

My code works with your example. Sorry, but I can't guess what else is going wrong without a reproducible example.

[Andrea Cinque]

Very weird. It does not work for me with your example

[Andrea Cinque]

Ok so I spotted the error.


it should be:

match("\(.*)\") regex

Thank you for the input!

[William Lisowski]

Running the code in post #2 fails for me as well. Post #2 says

match("\"(.*)\"")

Removing the (optional, per help moss) quotation marks surrounding the regular expression argument to the match() option, as shown in the picture in post #7, solves the problem.

match(\"(.*)\")

Replacing the optional surrounding quotation marks with Stata's compound double quotes, because the regular expression itself contains double quotes, solves the problem as well.

match(`"\"(.*)\""')

Let me add that post #6 would have been improved by copying the several lines of command and output from Stata's Results window and pasting it into a CODE block, as you did with the code in post #7. Screen shots are not as helpful as people think they are. Copyable text is helpful.

[Nick Cox]

I am puzzled now. I could have sworn that #2 was the code I used, but I am on a different computer, so can't check for that reason alone. Other way round, #7 isn't right either. But this works

moss abc , match(\"(.*)\") regex

[Leonardo Guizzetti]

#7 makes the same correction that you have done in #9. Alternatively, using compound double quotes around the regex pattern does also work.

moss abc , match(`"\"(.*)\""') regex

[Mike Lacy]

For amusement, here's a solution to the original problem using the built-in -split-

split abc, gen(s) parse(`"""')  // double quote is the parse character
reshape long s, i(abc) j(seq)
replace s = strtrim(s)
drop if (s== "")
drop abc seq

[William Lisowski]

Nick is correct, and I mistated things in post #8, confusing the picture in post #6 with the code block in post #7.

The code in post #7 produces

. moss abc , match("\(.*)\") regex
regex option: no subexpression in match(\(.*)\)
r(198);

because the backslash in front of the left parenthesis removes its special meaning as the start of a regex subexpression.

The code in the picture in post #6 is the same as the code in post #2, and produces

. moss abc , match("\"(.*)\"") regex

. gen wanted = cond(_match1 != "", _match1, abc)
_match1 not found
r(111);

I believe the problem lies in using double quotes to surround a string that itself contains double quotes.

Removing the (optional, per help moss) double quotes surrounding the argument to the match() option in the code from post #2 solves the problem.

. moss abc , match(\"(.*)\") regex

. gen wanted = cond(_match1 != "", _match1, abc)

. drop _* 

. l abc wanted

     +--------------------+
     |       abc   wanted |
     |--------------------|
  1. |       ABC      ABC |
  2. | DEF "XYZ"      XYZ |
  3. | GJK "LMN"      LMN |
  4. |       PQR      PQR |
     +--------------------+

Alternatively, replacing the optional surrounding double quotes in the code from post #2 with Stata's compound double quotes solves the problem as well.

. moss abc , match(`"\"(.*)\""') regex

. gen wanted = cond(_match1 != "", _match1, abc)

. drop _* 

. l abc wanted

     +--------------------+
     |       abc   wanted |
     |--------------------|
  1. |       ABC      ABC |
  2. | DEF "XYZ"      XYZ |
  3. | GJK "LMN"      LMN |
  4. |       PQR      PQR |
     +--------------------+

[Nick Cox]

I don't mind split solutions....

[Andrew Musau]

Double quotes are special characters in regular expressions, which need to be escaped. Therefore, a direct solution using Stata's regexm is possible.

clear
input str9 abc
"ABC"      
`"DEF "XYZ""'
`"GJK "LMN""'
"PQR"      
end

gen wanted= regexs(1) if regexm(abc,`"["\]([a-zA-Z]+)["\]"')
replace wanted= abc if missing(wanted)

Res.

. l

     +--------------------+
     |       abc   wanted |
     |--------------------|
  1. |       ABC      ABC |
  2. | DEF "XYZ"      XYZ |
  3. | GJK "LMN"      LMN |
  4. |       PQR      PQR |
     +--------------------+

[William Lisowski]

With the test data we've been using

gen wanted= regexs(1) if regexm(abc,`""([a-zA-Z]+)""')
replace wanted= abc if missing(wanted)

also results in

. list

     +--------------------+
     |       abc   wanted |
     |--------------------|
  1. |       ABC      ABC |
  2. | DEF "XYZ"      XYZ |
  3. | GJK "LMN"      LMN |
  4. |       PQR      PQR |
     +--------------------+

suggesting that in fact double quotes have no syntactic significance within regular expressions generally. What they do is confuse Stata's parser into misreading them as part of the Stata syntax rather than part of the regular expression.

Also, I now realize that by using compound double quotes the second moss solution from post #12 can have the regular expression simplified similarly.

. moss abc , match(`""(.*)""') regex

. gen wanted = cond(_match1 != "", _match1, abc)

. drop _* 

. l abc wanted

     +--------------------+
     |       abc   wanted |
     |--------------------|
  1. |       ABC      ABC |
  2. | DEF "XYZ"      XYZ |
  3. | GJK "LMN"      LMN |
  4. |       PQR      PQR |
     +--------------------+