How to colour bars in a histogram or graph bar

[Ruben Perez]

Hi there,

I have been trying to colour individual bars in a histogram or graph bar with percentages, but I don't get round to it without messing the bars heights. If we follow the following MWE:

sysuse auto,clear
hist mpg

I would like to colour the last 3 bars, just that.

Any help would be appreciated.

KR

[Andrew Musau]

There is a backstory to this. Five years ago, I taught an introductory course in econometrics and generated a histogram showing that you can get negative predicted probabilities with the linear probability model (LPM). Last year, looking through my slides, I could not figure out how I was able to shade a subset of those bars. After several failed attempts, I just figured that I had used the graph editor. So this is the code I used.

*THE LINEAR PROBABILITY MODEL (LPM)
webuse lbw
regress low age lwt i.race smoke ptl ht ui
predict yhat, xb
*NEGATIVE PREDICTED PROBABILITIES WITH THE LPM
hist yhat, bin(30) color(gray)
forval i=1/4{
      gr_edit .plotregion1.plot1.EditCustomStyle , j(`i') style(area(shadestyle(color(navy8))))
}

[John Mullahy]

*

[John Mullahy]

Here's another case where an undocumented command can come to the rescue. The undocumented command

twoway__histogram_gen

generates the underlying data for a histogram. (Note: two underscores after twoway)

Consider this code:

preserve
drop _all
sysuse auto
twoway__histogram_gen mpg, gen(h x, replace)
local wx=x[2]-x[1]
twoway (bar h x if x<30, color(orange) barwidth(`wx')) (bar h x if x>=30, color(ebblue) barwidth(`wx'))
restore

In general, even if perhaps tedious, including enough (bar h x if....) statements after twoway should allow a fair amount of flexibility in bar coloring.

[Nick Cox]

help twoway__histogram_gen

works, but Stata does mention the command under

help undocumented

so John Mullahy is right too. It's the non-documented commands that are esoteric.

That aside, here is another way to do it:

sysuse auto, clear
histogram mpg if mpg < 30, start(0) width(5) lcolor(orange) fcolor(orange*0.2) freq addplot(histogram mpg if mpg >= 30, start(30) width(5) freq lcolor(blue) fcolor(blue*0.2)) legend(off)