Creating a margins plot with confidence intervals

[Jessica Berrett]

Using the marginsplot command, I'm able to create a graph that looks like this:

However, is there a way in Stata to create a graph that looks like this?

[Scott Merryman]

-combomarginsplot- a user-written command by Nicholas Winter makes this straightforward.

ssc inst combomarginsplot

sysuse auto,clear
reg price c.mpg
margins, at(mpg = (10(5)50)) saving(linear, replace)
reg price c.mpg##c.mpg
margins, at(mpg = (10(5)50)) saving(quad, replace)
combomarginsplot linear quad, /// 
fileci1opts(recast(rarea) fcolor(538b%50))  fileci2opts(recast(rarea) fcolor(538r%50))

[Jessica Berrett]

Thank you so much Scott, this definitely got me closer!

Attached is what I was able to produce. The only thing I can't figure out now is why I have a solid and dotted line for each? Rather than just the dotted line. Also, how would I go about renaming file 1 and file 2?

This is the code I'm using:

xtreg lnTotalNRRR lnOVERHEAD lnTOTAL_PROGRAM_SERVICES lnASSETS_TOTAL_EOY AGE, fe
margins, at(lnOVERHEAD=(5(1)16)) saving(linear, replace)

xtreg lnTotalNRRR c.lnOVERHEAD##c.lnOVERHEAD lnTOTAL_PROGRAM_SERVICES lnASSETS_TOTAL_EOY AGE, fe
margins, at(lnOVERHEAD=(5(1)16)) saving(quad, replace)

combomarginsplot linear quad, fileci1opts(recast(rarea) fcolor(538b%50)) fileci2opts(recast(rarea) fcolor(538r%50))

[Scott Merryman]

You need to use the -file#opt()- with the lpattern() option. You can rename the legend keys using the -order()- option within -legend()-:

combomarginsplot linear quad, /// 
 fileci1opts(recast(rarea) lp(dash) lc(538b) fcolor(538b%50)) ///
 file1opt(lpattern(dash)) ///
 fileci2opts(recast(rarea) fcolor(538r%50)) /// 
 legend(order(1 "Linear CI" 3 "Linear Fit" 2 "Quadratic CI"  4 "Quadratic Fit") ///
  pos(6) row(2))

Note, I have my default scheme set as 538w (using Daniel Bischolf's g538schemes package), hence colors as 538r (a shade of red) and 538b (a shade of blue). If you do not have -538schemes- installed then those color options will not work.

To describe and install:

ssc desc g538schemes
ssc install g538schemes

[Jessica Berrett]

Excellent, many thanks again Scott!