esttab How do I drop the dependent variable from the list of variables in the output table?

[Michael Hensley]

I am using the following code.

esttab using "D:\Dropbox\Research\Dissertation\Data\2017\Work Station\employment.tex", /// here I'm telling stata that where I want to output the table and that I want to name the table _ht1_tab1
    se label style(tex) booktabs /// here I ask to report st. errors with "se", use var labels with "label", not sure what style(*) does but use it, and booktabs specifies the table format
    fragment noconstant replace star(+ .15 * .1 ** .05 *** .01) /// fragment is necessary for Latex environment, noconstant supresses reporting the constant, replace allows you to overwrite, and star(...) specifies coeff star levels
    stats(N r2 , labels(`"Observations"' `"\(R^{2}\)"')) /// this say the extra stats I want to include and how i want them labelled
    nodepvars nobase nonumbers

The output table lists the label of the dependent variable above the results column. Is it possible to remove this?

Thanks for your help.

[Andrew Musau]

esttab is from Stata Journal (as you are asked to explain) .

esttab using..., nomtitle

[Caecilia Lipowski]

I have encountered the same problem (the name of the dependent variable appearing above the list of the names of the regressors). Michael Hensley , have you found a solution?

[Andrew Musau]

I can only guess that #2 worked for Michael, but he did not close out this thread. He does not appear to be very active here, so your best bet will be to provide a reproducible example of your problem, which I believe is different from Michael's as the results column and the column containing the variable names are not the same.

[Caecilia Lipowski]

Hi Andrew,

Thank you for your reply. Here is a minimal reproducible example of my problem. I want to get rid off the bold "y" on the left side just above the regressor. This might be typical for the clogit command as I don't get it with other regression commands. Thank you!

clear
set obs 1000
gen y=round(runiform())
gen x=round(runiform(0,2))
gen group=floor(_n/2)

bysort group: gen time=_n
xtset group time

qui eststo clogit_0: clogit y x, group(group)

esttab clogit_0, mtitle("whatever")

[Andrew Musau]

Thanks for the reproducible example.

esttab clogit_0, mtitle("whatever") eqlabel("")

or even

esttab clogit_0, mtitle("whatever") eqlabel(none)

[Caecilia Lipowski]

Great, thank you!!! I somehow did not find this option myself!