[Clyde Schechter]

It depends on the intraclass correlation. If the intraclass correlation were 0, -regress- and -mixed- would give the same results. (Or, at least, they would if you also include -vce(cluster id)- in your -mixed- model, which, by the way, you should unless the number of patients is too small for that.) If the intraclass correlation is large, the error in relying on -regress- will be correspondingly large. The error you get largely is a matter of getting too small standard deviation, thus inflating the z-statistic and causing the p-value to be underestimated.

While it is true that a clinical audience would feel more comfortable with an ordinary linear regression than the mixed model, you don't need to torture them with the details of how mixed models work. In this situation, I would just say that the mixed model is just a fancier version of linear regression which better accounts the fact that the measurements of the two eyes in the same person are not independent observations. You don't have to explain anything more than that.

If your audience is at a very low level of sophistication so that even that is beyond them, you could offer an analogy. Political opinions tend to be (somewhat) correlated within households. An election poll that surveyed two people in each of 500 households would not be as informative as one that surveyed 1,000 unconnected people. Almost every college educated person can grasp that intuitively.

[Joseph Coveney]

The simplest approach (for me) would be make a regression analysis including the vce (cluster id ) option where id refers to the label of each subject. . . . Consider: . . .It would be easier for a non-statistician understad regression models rather than the mixed model.

But then consider, too: would it be easier for you to explain cluster-robust standard errors to your audience?

Your model does not have a predictor to distinguish the patient's eyes, for either anatomical side or dominance. So it seems that for this outcome measure you consider them exchangeable, and you appear to have outcome measurements for both eyes in all patients. In that case, why not have your cake and eat it too, just by taking the arithmetic average of the two measurements for each patient and using that as the outcome variable in a simple linear regression model?

In this balanced case, it gives identical results for the regression coefficients and their standard errors (p-values, confidence intervals etc.) as the mixed approach.

Run the code below to see for yourself.

version 18.0

clear *

// seedem
set seed 1687955160

drawnorm e0 e1, double sd(15 15) corr(1 0.5 \ 0.5 1) n(75)
generate `c(obs_t)' pid = _n

generate byte dis = mod(_n, 2)
generate byte age = runiformint(18, 90)

generate double xb = 100 + dis * 5 + age / 10 + 0 * dis * age
quietly reshape long e, i(pid) j(sid)

generate double mea = xb + e

*
* Begin here
*
bysort pid (sid): egen double avg = mean(mea)
regress avg i.dis c.age if !sid

mixed mea i.dis c.age || pid: , reml dfmethod(kroger) nolrtest nolog

exit

(Complete do-file and log file are attached for convenience.)

Given the statistical equivalence in your case, taking the average would seem to be easiest to do and easiest to explain to your audience.

[Dino F Vitale]

Thank you a lot both of you Clyde and Joseph,
you helped me solve the doubts I had in order to how to present to my collegues (and friends) a data analysis.
Your arguments will be of help also in the future.

Thank you a lot again.