How to interpret dummy interaction in probit models?

[Devon White]

Hello,
I am trying to understand the interpretation of binary interaction in probit model. I have a result of a probit model which looks at the effect of having a college degree (college grad = 1 or 0) for black women (black = 1 or 0) on having a high occupation job (high_occ = 1 or 0).

So, the result tells me that a black woman is less likely to have a job than other women, and college graduated black women are more likely to have a job than otherwise. But, how do I interpret the interaction term here?

Also, how would I go about doing and interpreting the marginal effect here? Please help me.

[Devon White]

As for the marginal effects in the equation above, I would guess it is margins black##collgrad, right?

So, would this interpretation be correct:
1) black women are 16% less likely to get a job
2) college graduated women are 41% more likely to get a job

3.1) if you are non-black and don't have a college degree, your chances of getting a job is 24% whereas if you are non-black and college educated you are 44% more likely to get a job?
3.2) if you are black a college educated you are 33% more likely to get a job while black non-educated women are only 11% likely to get a job?

Am I thinking in the right line here?

[David Benson]

Hi Devon, and welcome to Statalist!

Hopefully, this will help you get started (and others will come along and help answer your question on interpretation). But the best explanation I have found for interpreting interaction effects in logits or probits (using the Stata's margins command) is @Richard William's handout here.

He also has a more in-depth journal article on it (in case you need a source to cite) here

[Dimitriy V. Masterov]

You margins interpretation is incorrect. You are interpreting "as if" predictions like they were changes. See the example below for how to calculate what you want.

Using complete replicable code, rather than screenshots is super helpful.

. sysuse nlsw88, clear
(NLSW, 1988 extract)

. gen byte high_occ = occupation < 3 if occupation < .
(9 missing values generated)

. gen byte black = race == 2 if race < .

. drop if race==3
(26 observations deleted)

. probit high_occ i.black##i.collgrad, nolog

Probit regression                               Number of obs     =      2,211
                                                LR chi2(3)        =     127.07
                                                Prob > chi2       =     0.0000
Log likelihood = -1199.4399                     Pseudo R2         =     0.0503

---------------------------------------------------------------------------------
       high_occ |      Coef.   Std. Err.      z    P>|z|     [95% Conf. Interval]
----------------+----------------------------------------------------------------
        1.black |   -.485243    .084165    -5.77   0.000    -.6502032   -.3202827
                |
       collgrad |
  college grad  |   .5503463   .0730456     7.53   0.000     .4071795    .6935132
                |
 black#collgrad |
1#college grad  |   .1900196   .1650337     1.15   0.250    -.1334406    .5134798
                |
          _cons |  -.6947681   .0393595   -17.65   0.000    -.7719114   -.6176248
---------------------------------------------------------------------------------

. 
. margins black##collgrad         // predicted "as if" probabilities: .1687413 is phat as if everyone in the sample had race set to black

Predictive margins                              Number of obs     =      2,211
Model VCE    : OIM

Expression   : Pr(high_occ), predict()

-------------------------------------------------------------------------------------
                    |            Delta-method
                    |     Margin   Std. Err.      z    P>|z|     [95% Conf. Interval]
--------------------+----------------------------------------------------------------
              black |
                 0  |   .2904888   .0110303    26.34   0.000     .2688698    .3121077
                 1  |   .1687413   .0157189    10.73   0.000     .1379329    .1995497
                    |
           collgrad |
  not college grad  |   .2108013   .0098873    21.32   0.000     .1914225    .2301802
      college grad  |    .412974   .0216596    19.07   0.000     .3705219     .455426
                    |
     black#collgrad |
0#not college grad  |   .2436003   .0123351    19.75   0.000      .219424    .2677767
    0#college grad  |   .4425837    .024294    18.22   0.000     .3949683    .4901991
1#not college grad  |   .1189979   .0147942     8.04   0.000     .0900019    .1479939
    1#college grad  |   .3300971   .0463349     7.12   0.000     .2392824    .4209118
-------------------------------------------------------------------------------------

. margins r.black##r.collgrad // various differences of above

Contrasts of predictive margins
Model VCE    : OIM

Expression   : Pr(high_occ), predict()

--------------------------------------------------
               |         df        chi2     P>chi2
---------------+----------------------------------
         black |          1       40.20     0.0000
               |
      collgrad |          1       72.10     0.0000
               |
black#collgrad |          1        0.05     0.8280
--------------------------------------------------

----------------------------------------------------------------------------------------------
                                             |            Delta-method
                                             |   Contrast   Std. Err.     [95% Conf. Interval]
---------------------------------------------+------------------------------------------------
                                       black |
                                   (1 vs 0)  |  -.1217475   .0192029     -.1593844   -.0841105
                                             |
                                    collgrad |
         (college grad vs not college grad)  |   .2021726   .0238096      .1555066    .2488386
                                             |
                              black#collgrad |
(1 vs 0) (college grad vs not college grad)  |   .0121158   .0557507     -.0971536    .1213852
----------------------------------------------------------------------------------------------

. 
. // same differences calculated by hand
. di .168 - .290 
-.122

. di .412974  - .2108013
.2021727

. di (.3300971-.4425837) - (.1189979-.2436003)   
.0121158

. 
. // if you only care about the first two terms above
. margins, dydx(*) 

Average marginal effects                        Number of obs     =      2,211
Model VCE    : OIM

Expression   : Pr(high_occ), predict()
dy/dx w.r.t. : 1.black 1.collgrad

-------------------------------------------------------------------------------
              |            Delta-method
              |      dy/dx   Std. Err.      z    P>|z|     [95% Conf. Interval]
--------------+----------------------------------------------------------------
      1.black |  -.1217475   .0192029    -6.34   0.000    -.1593844   -.0841105
              |
     collgrad |
college grad  |   .2021726   .0238096     8.49   0.000     .1555066    .2488386
-------------------------------------------------------------------------------
Note: dy/dx for factor levels is the discrete change from the base level.

[Devon White]

Thank you for the suggestions Dmitry and David. In the output above where ‘black#collgrad’ is .0121, does that mean women who are black and college grad are 1.2% more likely to get a job than non-black and non-college educated women?


I am using different data for my paper but I am interested in testing the hypothesis that:

• There is no difference in the job outcome between black college-educated women and non-black, non-college educated women.

[No difference between black =1, collgrad =1 & black=0, collgrad=0]

• There is a difference in the job outcome between women who are black and non-college educated v/s women who are non-black and college educated.

[Difference in the job outcome between black=1, collgrad=0 & black = 0, collgrad=1]


How would I test that? Please let me know.

[Weiwen Ng]

Thank you for the suggestions Dmitry and David. In the output above where ‘black#collgrad’ is .0121, does that mean women who are black and college grad are 1.2% more likely to get a job than non-black and non-college educated women?
...

Let's clear something up. First, I don't see a 0.0121 in the margins output, so I have to assume you're referring to the last bit of Dimitry's code where he showed the results from

margins, dydx(*)

(Note: I can't copy and paste his output and have it retain proper formatting)

Second, margins after either logit or probit will present results in probability terms. That is, the average marginal effect (I hope I have that term right) of Black race is -12.175 percentage points. That is, on average, Black survey respondents are 12.175 percentage points less likely to get a job. They are not 12.175 percent less likely to get a job.

In your case, your hypotheses are:

• There is no difference in the job outcome between black college-educated women and non-black, non-college educated women.
• There is a difference in the job outcome between women who are black and non-college educated v/s women who are non-black and college educated.

The most direct route I can think of is to use the -dydx- operator, but I think you have to modify Dimitry's code:

margins, dydx(black) over(college)

That is, what's the average marginal effect of Black race in women with college education (you're expecting 0), and in women without college education (you're expecting something other than zero)?

A side note: the FAQ suggests not posting screenshots. They are not readable on all platforms. Posting results in the code delimiters (as Dimitry and I have) is guaranteed to be readable on computers. Admittedly, on my iPhone SE, it doesn't format so well, but that is a fairly small phone (for this day and age, anyway).

[Devon White]

Hi Weiewn,

Let's clear something up. First, I don't see a 0.0121 in the margins output, so I have to assume you're referring to the last bit of Dimitry's code where he showed the results from

I meant in the part where Dimitriy typed:

 margins r.black##r.collgrad

----------------------------------------------------------------------------------------------
                                             |            Delta-method
                                             |   Contrast   Std. Err.     [95% Conf. Interval]
---------------------------------------------+------------------------------------------------
                                       black |
                                   (1 vs 0)  |  -.1217475   .0192029     -.1593844   -.0841105
                                             |
                                    collgrad |
         (college grad vs not college grad)  |   .2021726   .0238096      .1555066    .2488386
                                             |
                              black#collgrad |
(1 vs 0) (college grad vs not college grad)  |   .0121158   .0557507     -.0971536    .1213852
----------------------------------------------------------------------------------------------

Would the interpretation here be correct to say that college-educated black females are 1.2 percentage points more likely to get a job than non-college educated non-black women? I am thinking the output above is showing the result of job outcome for the group (black = 1, college =1) relative to the group (black =0, college=0).

But, how would I go about seeing how the job prospect looks for (black = 1 and college grad =0) compared to the groups who are (black = 0 and college grad =1).

I tried the code that you suggested, but I think it only gives the job outcome for blacks when they are educated v/s not educated.

. margins, dydx (black) over( collgrad )

Average marginal effects                        Number of obs     =      2,211
Model VCE    : OIM

Expression   : Pr(high_occ), predict()
dy/dx w.r.t. : 1.black
over         : collgrad

-----------------------------------------------------------------------------------
                  |            Delta-method
                  |       dy /dx   Std. Err.      z    P>|z|     [95% Conf. Interval]
------------------+----------------------------------------------------------------
1.black           |
         collgrad |
not college grad  |  -.1246024   .0192619    -6.47   0.000    -.1623551   -.0868497
    college grad  |  -.1124866   .0523175    -2.15   0.032    -.2150271   -.0099462
-----------------------------------------------------------------------------------

[Dimitriy V. Masterov]

The (.3300971-.4425837) - (.1189979-.2436003) = .0121158 is the black effect for college grads versus the black effect for non-college grads.

For the latter, you can do something like this:

margins, at(black = 1 collgrad=1) at(black = 0 collgrad=0) 
margins, at(black = 1 collgrad=1) at(black = 0 collgrad=0) contrast(atcontrast(ar._at) wald)

This creates the two predictions you care about and then the contrast option differences them.