"find and replace" words in Stata code

[tim bradshaw]

I often find I want to make my generic Stata code suit the specifics of my dataset/output.

So, in the example below, I want to replace the generic word "outcome" (and all compound words containing the word "outcome") with a more specific word like "colon_cc":

gen outcome1 = 0
replace outcome1 = 1 if icd >= "C180" & icd <= "C188"
gen outcome2 = 0
replace outcome2 = 1 if icd == "C189"

gen outcome_grp = 0
replace outcome_grp = 1 if outcome1 == 1 | outcome2 == 1

stset exit, fail(outcome1) enter(entry) origin(entry) id(sysno)
stcox i.exposure i.other_vars
regsave 1.exposure using "dir\results.dta", ci pval addlabel(description, outcome1) append

stset exit, fail(outcome2) enter(entry) origin(entry) id(sysno)
stcox i.exposure i.other_vars
regsave 1.exposure using "dir\results.dta", ci pval addlabel(description, outcome2) append

stset exit, fail(outcome_grp) enter(entry) origin(entry) id(sysno)
stcox i.exposure i.other_vars
regsave 1.exposure using "dir\results.dta", ci pval addlabel(description, outcome_grp) append

...and so on.

Currently I use the "find and replace" function in MS Word to do this! (I'm sure many Stata users would regard this as a sin, but I'm still very much learning.)

Any advice would be greatly appreciated!

With regards

[Attaullah Shah]

If you are using Stata DO file, then why not use the "find and replace" Short-cut Ctr+H

[tim bradshaw]

Thank you so much for your reply.

I was hoping there might be a more elegant solution that would preserve the generic code, perhaps a local macro at the start to tell Stata that whenever it comes across the word "outcome" to treat it as "colon_cc"?

Again, many thanks for your offered suggestion.

With regards

[Nick Cox]

If you change all instances of

outcome

to

`outcome'

and write before any of those

local outcome outcome

then next time around you can change that last line to

local outcome colon_cc

and you have what you want.

Otherwise I want to point out that

gen outcome1 = 0
replace outcome1 = 1 if icd >= "C180" & icd <= "C188"

gen outcome2 = 0
replace outcome2 = 1 if icd == "C189"  

gen outcome_grp = 0
replace outcome_grp = 1 if outcome1 == 1 | outcome2 == 1

can be cut down to

gen outcome1 = icd >= "C180" & icd <= "C188"
gen outcome2 = icd == "C189"
gen outcome_grp = outcome1 == 1 | outcome2 == 1

or even

gen outcome1 = inrange(icd, "C180", "C188")
gen outcome2 = icd == "C189"
gen outcome_grp = outcome1 | outcome2

following principles explained at https://www.stata.com/support/faqs/d...true-and-false

[tim bradshaw]

That's marvellous, thanks so much Nick.
And for your other suggestions too - my coding is horribly inefficient and these tips literally transform my life working with Stata!

[tim bradshaw]

Thanks again, Nick, for your very helpful earlier response.

It's very useful to be able to use

local outcome colon_cc

to create variables such as `outcome'_grp and `outcome'_grp_broad, without having to change my lengthy generic code.

I was wondering if it's possible to do a similar thing but with global macros?

The trouble is that

global outcome colon_cc

is not compatible with $outcome_grp (because, unlike the local macro, the global macro doesn't know to stop in the middle of the word).

I hope that makes sense.

Kind regards

[Nick Cox]

Documented problem and solution. See 18.3.10 in https://www.stata.com/manuals/u18.pdf

. global outcome "frog"

. di "|$outcome_group|"
||

. di "|${outcome}_group|"
|frog_group|

[tim bradshaw]

perfect, thanks