Saving coefficients statsby

[Priyesh VP]

Hi,

I was running the following command to generate coefficients for group wise regression.
Code:

statsby n=e(N) _b , by(nicyear) clear : regress Ac_w b_w rev_w recc_w PPE_w roa_w

I have panel data around 20 years. I wanted to run the regression in each "nicyear" combination and get the coefficients, which I require for further analysis. But the above code generates coefficients by replacing the current data. I want to get the coefficients displayed in separate columns in my existing data set.
Each nicyear combination will have many companies. But the coefficients generated will be same for firms under same nicyear combination
A snapshot of my data is attached below:

Can someone help me: I need coefficients of statsby output in separate columns

Thanks

[Nick Cox]

Do please note our advice on data examples. FAQ Advice #'12,

You could just merge back with your original data.

. sysuse auto, clear
(1978 Automobile Data)

. save myauto
file myauto.dta saved

. statsby, by(foreign) : regress mpg weight
(running regress on estimation sample)

      command:  regress mpg weight
           by:  foreign

Statsby groups
----+--- 1 ---+--- 2 ---+--- 3 ---+--- 4 ---+--- 5 
..

. merge 1:m foreign using myauto
(label origin already defined)

    Result                           # of obs.
    -----------------------------------------
    not matched                             0
    matched                                74  (_merge==3)
    -----------------------------------------

[Clyde Schechter]

Another approach is to use -runby-, written by Robert Picard and me, available from SSC:

capture program drop one_regression
program define one_regression
    regress Ac_w b_w rev_w recc_w PPE_w roa_w
    foreach v of varlist b_w rev_w recc_w PEE_w roa_w {
        gen b_`v' = _b[`v']
    }
    gen n = e(N)
    exit
end

runby one_regression, by(nicyear) status

The advantage of this approach is that if your data set is very large, it will be much faster than using -statsby-.

Asides:

1. Please read the FAQ for advice about effective posting. Screenshots of data sets are not helpful. While they give a general impression of the data, there is no way to import data from a screenshot into Stata. Because you did not provide a usable example of your data, the code shown above is not tested and may contain errors. FAQ #12 explains the use of the -dataex- command, which enables you to provide a complete and faithful replica of your example data that can be imported into Stata with a simple copy/paste operation by anyone who wants to help you. When you are asking for help with coding, you are more likely to get a quick and helpful response if you post an example with -dataex-.

2. Stata is not a spreadsheet, and thinking about it as if it were can lead you astray. When using Stata, you should try to banish from your mind the experience you have using spreadsheets. One way to help do that is to not use spreadsheet terminology when describing things in Stata. In particular, Stata data sets do not have columns: they have variables. Stata data sets also do not have rows: they have observations.

[Priyesh VP]

Thanks for the Help...!..

I should have used dataex command to show the data structure.Anyway point noted..