Flag words in a var with all characters uppercase

[Katherine A.]

I wonder if someone knows a quick and easy way to select words in a string where all the characters are uppercase.
I want to exclude numbers, symbols, spaces and everything else. I only need to flag words with all upper case.

Something like this:
mystring flag
BMW 1
BMW9 0
XS.9 0
XA 1
xA 0
xA. 0

[Mike Lacy]

Don't quite get your use of "exclude" here, but I understand that you want to flag any string that contains only upper case alphabetic characters. Strings containing any other character are to be identified as "not all upper."

clear
input str20 mystring
"BMW"
"BMW9 "
"XS.9"
"XA1"
"XA"
"xA.0"
end
//
gen slength = strlen(mystring)
quiet summ slength
local maxlen = r(max)
gen byte allupper = 1
gen str next = ""
forval i = 1/`maxlen' {
  replace next = substr(mystring, `i', 1) if (`i' <= slength)
  replace allupper = 0 if (allupper == 1) & !inrange(next, "A", "Z")
}

[Bjarte Aagnes]

To flag words with all upper case regular expressions may be used.

If you have only ASCII (range) characters:

gen byte flag = regexm(mystring,"^[A-Z]+$")

If characters outside the ASCII range:

gen byte flag = ustrregexm(mystring,"^[\w]+$") & !ustrregexm(mystring,"[\d_]+") & mystring == upper(mystring)

The latter might work or need adaption and the Stata reg-ex documentation could be better.

[Katherine A.]

Thank you, both! You save my day...

[Bjarte Aagnes]

PS.The unicode regex in #3 should be replaced with:

gen byte flag = ustrregexm(mystring,"^[\p{Uppercase_Letter}]+$")

or even shorter

gen byte flag = ustrregexm(mystring,"^[\p{Lu}]+$")

see http://www.regular-expressions.info/unicode.html