Plotting fitted line from multivariate linear & quadratic regression

[Albert Henry]

Dear Statalisters,

I am wondering whether there is a way to plot the fitted line from multivariate linear & quadratic regressions.
For example, in simple linear regression, I would do it this way:

sysuse auto, clear
reg mpg weight
predict mpg_hat1
line mpg_hat1 weight, sort

*or maybe simply
twoway  (lfit mpg weight)

However, when I try to do this in multivariate linear regression:

sysuse auto, clear
reg mpg weight length turn
predict mpg_hat2
line mpg_hat2 weight, sort

It gives me a jagged line plot since the predicted values take into account all the covariates included in the model.

Regarding this, I'd like to ask:
Is it possible to plot a linear fitted line for the multivariate model (i.e. just take into account the coefficient for the variable weight after adjusting for length and turn )

I would also like to fit a multivariate quadratic model, but I am guessing the solution would be similar.

Thanks for your help!

Regards,
Albert

[Maarten Buis]

See http://www.maartenbuis.nl/wp/inter_q...ter_quadr.html

[Roman Mostazir]

If you simply want to plot the linear slope of weight holding the effect of length and turn, use of 'function' may help:

sysuse auto, clear

reg mpg c.weight length turn //Linear model

twoway (function mpg=_b[_cons]+_b[weight]*x, range(1800 4800) xtitle(weight))

//For quadratic slope of weight:

reg mpg c.weight##c.weight length turn //quadratic model

twoway (function mpg=_b[_cons]+_b[weight]*x +_b[weight]*x^2, range(1800 4800) xtitle(weight))

[Bruce Weaver]

Roman, your code seems to be holding variables length & turn constant at 0, which is unrealistic. Why not just use margins & marginsplot instead?

sysuse auto, clear
// Linear fit
regress mpg c.weight length turn //Linear model
quietly margins, at(weight=(1800(100)4800))
marginsplot, recast(line) recastci(rarea)
// Quadratic fit
regress mpg c.weight##c.weight length turn //quadratic model
quietly margins, at(weight=(1800(100)4800))
marginsplot, recast(line) recastci(rarea)

Also, in your second example (for the quadratic fit), I think you need to replace _b[weight]*x^2 with _b[c.weight#c.weight]*x^2.

HTH.

[Roman Mostazir]

Bruce I agree that is unrealistic. However, my answer#3 relates to the question asked in the original post#1 referring to the bold part (if I understood it correcly). Thanks for correcting the quadric typo.

[Albert Henry]

Hi Maarten, Roman, and Bruce,

Thanks for your suggestions. For now, I am more inclined to use the margins and marginsplot command as suggested by Bruce.

If I may ask further, is it possible to overlay two or more models created using marginsplot in the same graph?
For example, in the code provided by Bruce at post #4, is there a way to combine the linear and quadratic fit models in the same graph?

Regards,
Albert

[Bruce Weaver]

Hello Albert. Does this give you what you want?

scatter mpg weight || lfit mpg weight || qfit mpg weight

[Roman Mostazir]

#6: If you are after overlaying two predictions from two 'margins' post-estimations, use the user-written program 'combomarginsplot'written by Nicholas Winter after margins. Type -ssc install combomarginsplot- to install the programme. Example of Bruce's commands with margins and overlaying the plots with combomarginsplot:

qui regress mpg c.weight length turn //Linear model
qui margins, at(weight=(1800(100)4800)) noci saving(x1, replace)

qui regress mpg c.weight##c.weight length turn //quadratic model
margins, at(weight=(1800(100)4800))  noci saving(x2, replace)

qui combomarginsplot x1 x2 , noci plotdim(_filenumber) ///
     label("Linear" "Qadratic") name(fixed, replace)

[Albert Henry]

Hi Bruce and Roman,

Thanks for your help!
I think Bruce's suggestion in #7 will only plot the univariate model (with only weight as covariate) so I will go with Roman's suggestion in #8 for now

Best,
Albert