Replicating Blundell and Bond (1998) using -xtdpd-

[Futoshi Narita]

Dear all,

Using xtdpd, I'm trying to replicate Table 4 of Blundell and Bond (1998) "Initial conditions and moment restrictions in dynamic panel data models" - Journal of Econometrics 87, 115-143. I have searched for past threads on this topic, but I cannot find any (although several people tried to replicate what xtdpd does by using gmm).

So far, I have been successful the third column, no other column has been replicated.

The third column is exactly replicated as follows.

webuse abdata, clear

*** Blundel and Bond (1998), Exact replication of "1976-1984 GMM DIF" - third column of Table 4 ***
xtdpd L(0/1).n L(0/1).(w k) yr1978-yr1984, div(yr1978-yr1984) dgmmiv(n) dgmmiv(w k, lag(2 .)) noconstant

The results are exactly the same as the third column of Table 4, which is great.

However, I cannot replicate the fourth column, but the closest replication is as follows:

webuse abdata, clear

*** Blundel and Bond (1998), Close replication of "1976-1984 GMM SYS" - fourth column of Table 4 ***
xtdpd L(0/1).n L(0/1).(w k) yr1978-yr1984, div(yr1978-yr1984) dgmmiv(n) dgmmiv(w k, lag(2 .)) lgmmiv(n w k, lag(1)) hascons

The results are different from the fourth column of Table 4, despite the success regarding the third column above.

In my understanding, this code utilizes the same orthogonal conditions as stated in footnotes of Table 4 (except for the constant term for the level equation, which is not clear whether or not being included; here I included it because it gives me closer estimates, but not sure if this is correct either). I have tried xtdpdsys as well, but I cannot do what I would like to do using its syntax (e.g., it includes other orthogonal conditions that I don't want to include).

As I've been spending so much time on this, I really appreciate it if anyone could tell me how to replicate the fourth column (as well as the first and the second columns).

Best Regards,
Futoshi

--
Futoshi Narita (Mr.)
Economist
Developing Markets Strategy Unit
Strategy, Policy, and Review Department
International Monetary Fund
TEL: 202-623-7143
Email: [email protected]

[Sebastian Kripfganz]

The short answer is: You cannot.

As Doornik et al. (2012, pp. 13-14) report, there have been coding errors in the original program used to generate the results by Blundell and Bond (1998). Doornik et al. (2012) provide revised results in their Table 1. Column 3 is identical in both papers. The following code replicates these revised results for columns 3 and 4:

webuse abdata

// column 3, Table 4, Blundell and Bond (1998), identical to colum 3, Table 1, Doornik et al. (2012)
xtdpd L(0/1).n L(0/1).w L(0/1).k yr1978-yr1984, dgmm(n w k) div(yr1978-yr1984) nocons vce(robust)

// column 4, Table 1, Doornik et al. (2012)
xtdpd L(0/1).n L(0/1).w L(0/1).k yr1978-yr1984, dgmm(n w k) lgmm(n w k) liv(yr1978-yr1984) hascons vce(robust)

Notice that these authors report coefficients and standard errors for the one-step GMM estimator. However, the reported Sargan test statistics are based on the corresponding two-step GMM estimator and can be replicated as follows:

// Sargan test in column 3, Table 4, Blundell and Bond (1998), identical to colum 3, Table 1, Doornik et al. (2012)
xtdpd L(0/1).n L(0/1).w L(0/1).k yr1978-yr1984, dgmm(n w k) div(yr1978-yr1984) nocons twostep
estat sargan

// Sargan test in column 4, Table 1, Doornik et al. (2012)
xtdpd L(0/1).n L(0/1).w L(0/1).k yr1978-yr1984, dgmm(n w k) lgmm(n w k) liv(yr1978-yr1984) hascons twostep
estat sargan

Doornik et al. (2012) also revise the first two columns. Yet, I am still unable to replicate these results for the restricted sample.

References:

• Blundell, R. and S. Bond (1998). Initial conditions and moment restrictions in dynamic panel data models. Journal of Econometrics 87 (1), 115-143.
• Doornik, J. A., M. Arellano, and S. Bond (2012). Panel data estimation using DPD for Ox. http://fmwww.bc.edu/ec-p/software/ox/dpd.pdf

[Futoshi Narita]

Thank you so much Sebastian! This problem has been a long-lasting headache to me, so I really appreciate your very useful reply!

I will definitely read the Doornik et al. (2012).

Again, thank you very much!
Futoshi