Drop observations by group size

[Max Crichton]

I have the following data:

* Example generated by -dataex-. To install: ssc install dataex
clear
input matcheducage
 1
 2
 3
 4
 5
 6
 7
 7
 7
 7
 7
 8
 9
 9
10
11
12
12
13
14
end

I would like to drop the groups from my dataset which have only one observation, i.e. in this case groups 1,2,3,4,5,6,8 and so on.

Would you have any idea on how I could code this?

Thank you very much in advance for your suggestions!

Best,

Max

[Sebastian Kaumanns]

Assuming the variable whose values range from 1 to 14 in your example is called "group", I would use:

gen help=group!=.
egen help2=sum(help)
drop if help2==1
drop help help2

[Carlo Lazzaro]

Max:
you may want to try:

duplicates tag matcheducage, g(flag) 
drop if flag==0

[Nick Cox]

  
input matcheducage
 1
 2
 3
 4
 5
 6
 7
 7
 7
 7
 7
 8
 9
 9
10
11
12
12
13
14
end

bysort matcheducage : drop if _N == 1

Note that Sebastian's code won't work. The constructed variable help2 is constant across the dataset and can't possibly discriminate between singletons and duplicates.

Carlo's code would work.

[Sebastian Kaumanns]

Thanks for the correction Nick. I forgot the most important part:

gen help=group!=.
bys group: egen help2=sum(help)
drop if help2==1
drop help help2

[Nick Cox]

Sebastian: Your strategy clearly makes sense. It could be simplified thus:

 
bys group: egen help2 = count(group)
drop if help2 == 1
drop help2

You are counting non-missing values. But doing that by group: automatically segregates the missing values of group and so the code need not be fastidious about ignoring them.

If there are missing values of group then your help2 is 0 and those values will not be dropped.

So your code is essentially equivalent to my code.

(There is further small print to add if there are system or extended missing values.)

[Max Crichton]

Thank you very much for the quick replies! I ran Carlo's code and it worked out fine!

Best,
Max