Tempfile save

[Rochelle Zhang]

Dear Statalisters,

Here is a demonstration of my data:

clear
input byte(treated strat_pre)
0 18 
0 19 
0 15 
0 19 
1 21 
1 22 
1 21 
1 24 
end

I want to save two sub datasets for treated=0 and 1 separately.

My question is if I should use preserve , then restore ,

tempfile treat
keep if treated==1
save `treat'

tempfile treat
keep if treated==0
save `control'

I think the code needs to be modified.

Best,
Rochelle

[Clyde Schechter]

Yes, I see two problems. First, after the -keep if treat == 1- statement, all of the data with treat != 1 is gone. So when you later try to -keep if treated == 0-, you end up with nothing. You need to bring the original data back in after the first save. The other problem is that you have declared the tempfile treat twice, and never declared the tempfile control. So the corrected code looks like this:

preserve // SAVE THE ORIGINAL DATA
tempfile treat
keep if treated == 1
save `treat'

restore // BRING BACK THE ORIGINAL DATA
tempfile control
keep if treated == 0
save `control'

[Raoul Reulen]

I would use:

. savesome

for this

[Nick Cox]

savesome is from SSC. Note that internally savesome is just using preserve too.

[Rochelle Zhang]

Thanks Clyde, Raoul, and Nick !

This would be a naive question - how would i located and refer to the tempfiles `treat' `control', I need do more calculations with respect to each dataset.

e.g. I need compute the standard deviation of Stra_pre.

[Clyde Schechter]

how would i located and refer to the tempfiles `treat' `control'

Exactly in that way! Any place where you could use a filename in a Stata command, you can just type `treat', or `control' in order to do with those files, whatever you would do with a regular Stata file. Examples:

use `treat', clear

append using `control'

//etc.

The difference between a tempfile and a regular file is just that once you leave the local environment (do-file, program, or command window) in which it was declared, it vanishes. It vanishes in two ways: the name will no longer refer to anything, and the file itself will have been deleted. So for example:

// THIS IS OK
program define myprogram
     ....
     tempfile treat
     save `treat'
     .... do other stuff

     .... now bring back data saved in `treat'

     use `treat', clear
     ... do more stuff
     exit
end

// BUT THIS IS NOT
program define myprogram
     ....
     tempfile treat
     save `treat'
     .... do other stuff
     exit
end

...now bring back data saved in `treat'
use `treat', clear // WILL BREAK: NEITHER THE NAME `treat' NOR THE FILE EXIST ANY LONGER

Similarly, if you create a file `control' in a do-file and then attempt to refer to it in a command that you type in the Command Window, Stata will say that there is no such file. And also similarly, if you run a do-file a few lines at a time, if you create `control' at one time and try to access it another time, you will fail.

Hope this helps.

[Rochelle Zhang]

Thanks again Clyde !

You always give most helpful response.

Best,
Rochelle